groovy - 在 Groovy 中拥有可重用元类代码的优雅方式是什么？

Question

我想对我的一些类应用元编程转换，比如说通过添加 printXxx 方法，如下所示：

class Person {
  String name
}

def p = new Person()
p.printName() // does something

我有一个粗略的想法，一旦我有了一个元类，如何做到这一点：

Person.metaClass.methodMissing = { name, args ->
  delegate.metaClass."$name" = { println delegate."${getPropName(name)}" }
  delegate."$name"(*args)
}

现在我如何把这段代码变成一个可重用的“库”？我想做类似的事情：

@HasMagicPrinterMethod
class Person {
  String name
}

或者

class Person {
  String name

  static {
    addMagicPrinters()
  }
}

Answer 1

定义要添加为特征的行为

trait MagicPrinter {                           
  void printProperties() {  
    this.properties.each { key, val ->
      println "$key = $val"
    }
  }          
}

然后将此特征添加到一个类

class Person implements MagicPrinter {
  String name
}

现在使用它！

new Person(name: 'bob').printProperties()

Answer 2

您可以采用混合方法：

class AutoPrint {
    static def methodMissing(obj, String method, args) {
        if (method.startsWith("print")) {
            def property = (method - "print").with { 
                it[0].toLowerCase() + it[1..-1] 
            }
            "${obj.getClass().simpleName} ${obj[property]}"
        }
        else {
            throw new NoSuchMethodException()
        }
    }
}

您可以将其与静态块混合：

class Person {
    static { Person.metaClass.mixin AutoPrint }
    String name
}

def p = new Person(name: "john doe")


try {
    p.captain()
    assert false, "should've failed"
} catch (e) {
    assert true
}

assert p.printName() == "Person john doe"

或使用 expandoMetaClass：

class Car {
    String model
}

Car.metaClass.mixin AutoPrint

assert new Car(model: "GT").printModel() == "Car GT"

_{因为 7 个月后是新的“现在”:-)}