8

我想做的是只编写 Lazy C++ .lzz 文件，然后在构建之前运行 lzz 以生成将内置到最终应用程序中的 .cpp 和 .h 文件，有点像 moc 如何与 Qt 一起工作。

有没有办法做到这一点？

4

3 回答 3

9

这是如何执行此操作的示例...首先您需要找到lzz程序，为此使用find_program命令：

find_program(LZZ_COMMAND lzz)

这设置LZZ_COMMAND为编译器的路径。然后使用 CMake 自定义命令将 LZZ 文件编译为它们的 C++ 头文件/实现文件：

add_custom_command(
    OUTPUT ${output}
    COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})

这会在当前构建目录中生成文件，以防您进行源外构建。您还需要指定输出是生成的文件：

set_source_files_properties(${output} PROPERTIES GENERATED TRUE)

把它们放在一起，你会得到一个 CMakeLists.txt 文件，如下所示：

cmake_minimum_required(VERSION 2.8)
project(lazy_test)
find_program(LZZ_COMMAND lzz)
function(lazy_compile filename)
    get_filename_component(base ${filename} NAME_WE)
    set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
    set(output ${base_abs}.cpp ${base_abs}.h)
    add_custom_command(
        OUTPUT ${output}
        COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})
    set_source_files_properties(${output} PROPERTIES GENERATED TRUE)
endfunction()
lazy_compile(${CMAKE_CURRENT_SOURCE_DIR}/example.lzz)
add_executable(test example.cpp example.h)

您可能还希望最终向 lzz 添加包含路径和其他选项。如果您将所有 Lazy C++ 内容放入一个模块文件中，并从 CMakeLists.txt 中包含它，它会更简洁一些。但这是基本思想。

于 2010-04-22T11:59:47.270 回答
6

我只是想分享我的 CMakeLists.txt，它建立在 Richq 的脚本之上。*.cpp 和 *.hpp 文件现在正确地依赖于 *.lzz 文件。*.lzz 文件被添加到项目中（它回答了上面缺席的问题），但使用 source_group 命令与生成的文件分开。

对我来说，唯一剩下的问题是无法为 *.lzz 文件编译当前文件。

cmake_minimum_required(VERSION 2.8)

PROJECT(LzzTest)

find_program(LZZ_COMMAND lzz.exe)

# Syntax: 
#   add_lzz_file(<output> <lzz file>)
# Adds a build rule for the specified lzz file. The absolute paths of the generated 
# files are added to the <output> list. The files are generated in the binary dir.
# 
# TODO: Support for generating template files etc.
function(add_lzz_file output filename)
  # Only process *.lzz files
  get_filename_component(ext ${filename} EXT)
  if(NOT ext STREQUAL ".lzz")
    return()
  endif()

  set(header_extension "hpp")
  get_filename_component(base ${filename} NAME_WE)
  set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
  set(outfiles ${base_abs}.cpp ${base_abs}.${header_extension})
  set(${output} ${${output}} ${outfiles} PARENT_SCOPE)

  #message("outfiles=${outfiles}, DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${filename}")
  add_custom_command(
    OUTPUT ${outfiles}
    COMMAND ${LZZ_COMMAND} 
      -o ${CMAKE_CURRENT_BINARY_DIR} # output dir
      -hx ${header_extension}
      -sl -hl -il -tl -nl -x # insert #line commands w/ absolute paths
      -sd -hd -id -td -nd # don't output files that didn't change
      ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
    DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/${filename}"
  )

  set_source_files_properties(${outfiles} PROPERTIES GENERATED TRUE)
endfunction()

include_directories(${CMAKE_CURRENT_BINARY_DIR})

set(SOURCES
  A.lzz
  B.lzz
  main.cpp
)

foreach(file ${SOURCES})
  add_lzz_file(GENERATED_SOURCES ${file})
endforeach()

source_group("" FILES ${SOURCES})
source_group(generated FILES ${GENERATED_SOURCES})

add_executable(LzzTest ${SOURCES} ${GENERATED_SOURCES})
于 2012-03-12T14:54:27.577 回答
0

对于制作：

sourcecode.h sourcecode.cpp: sourcecode.lzz
<TAB>lazy-cpp sourcecode.lzz

用正确的值填写 sourcecode.h、sourcecode.cpp 和lazy-cpp。我不认识他们。

于 2010-04-21T23:08:09.370 回答