3

我编写了一个 build.gradle 脚本来自动从给定的 URL 下载 hazelcast。之后，文件被解压缩，只有 mancenter.war 以及原始 zip 文件保留在目标目录中。后来这个战争文件被引用用于码头运行。

尽管如此，虽然我为我的两个任务定义了 output.file，但是当我执行 gradle clean 时这些文件并没有被清理。因此，我想知道当我执行 gradle clean 时我必须做什么才能删除下载和解压缩的文件。这是我的脚本：

顺便说一句，如果您对如何增强脚本有任何建议，请不要犹豫告诉我！

apply plugin: "application"

dependencies {
    compile "org.eclipse.jetty:jetty-webapp:${jettyVersion}"
    compile "org.eclipse.jetty:jetty-jsp:${jettyVersion}"
}

ext {
    distDir = "${projectDir}/dist"

    downloadUrl = "http://download.hazelcast.com/download.jsp?version=hazelcast-${hazelcastVersion}"
    zipFilePath = "${distDir}/hazelcast-${hazelcastVersion}.zip"
    warFilePath = "${distDir}/mancenter-${hazelcastVersion}.war"

    mainClass = "mancenter.MancenterBootstrap"
}

task downloadZip() {
    outputs.file file(zipFilePath)
    logging.setLevel(LogLevel.INFO)
    doLast {
        ant.get(src: downloadUrl, dest: zipFilePath)
    }
}

task extractWar(dependsOn: downloadZip) {
    outputs.file file(warFilePath)
    logging.setLevel(LogLevel.INFO)
    doLast {
        ant.unzip(src: zipFilePath, dest: distDir, overwrite:"true") {
            patternset( ) {
                include( name: '**/mancenter*.war' )
            }
            mapper(type:"flatten")
        }
    }
}

task startMancenter(dependsOn: extractWar, type: JavaExec) {
    main mainClass
    classpath = sourceSets.main.runtimeClasspath
    args warFilePath
}

更新

我找到了这个链接，它描述了如何在调用清理任务时提供要删除的其他位置。基本上你可以做某事。像这样：

clean{
    delete zipFilePath
    delete warFilePath
}
4

2 回答 2

6

我从源代码中得到确认，清理任务只是删除了构建目录。它假定您要清理所有内容，并且所有任务输出都在此构建目录中的某个位置。

因此，最简单和最佳的做法是仅将输出存储在构建目录下的某个位置。

于 2014-11-09T16:29:15.850 回答
3

您可以像这样添加要清理的任务：

clean.dependsOn(cleanExtractWar)
clean.dependsOn(cleanDownloadZip)

cleanTaskName 是一个虚拟任务，将清除 TaskName 的所有输出。

于 2015-10-06T14:06:33.617 回答