96

有没有办法使 TSQL 变量保持不变?

4

12 回答 12

63

不,但是您可以创建一个函数并在其中对其进行硬编码并使用它。

这是一个例子:

CREATE FUNCTION fnConstant()
RETURNS INT
AS
BEGIN
    RETURN 2
END
GO

SELECT dbo.fnConstant()
于 2008-08-25T19:05:30.060 回答
36

Jared Ko 提供的一种解决方案是使用伪常量

SQL Server:变量、参数或文字中所述 或者……常数?

伪常数不是变量或参数。相反,它们只是具有一行的视图,并且有足够的列来支持您的常量。通过这些简单的规则,SQL 引擎完全忽略了视图的值,但仍然根据其值构建执行计划。执行计划甚至没有显示视图的连接!

像这样创建:

CREATE SCHEMA ShipMethod
GO
-- Each view can only have one row.
-- Create one column for each desired constant.
-- Each column is restricted to a single value.
CREATE VIEW ShipMethod.ShipMethodID AS
SELECT CAST(1 AS INT) AS [XRQ - TRUCK GROUND]
      ,CAST(2 AS INT) AS [ZY - EXPRESS]
      ,CAST(3 AS INT) AS [OVERSEAS - DELUXE]
      ,CAST(4 AS INT) AS [OVERNIGHT J-FAST]
      ,CAST(5 AS INT) AS [CARGO TRANSPORT 5]

然后像这样使用:

SELECT h.*
FROM Sales.SalesOrderHeader h
JOIN ShipMethod.ShipMethodID const
    ON h.ShipMethodID = const.[OVERNIGHT J-FAST]

或者像这样:

SELECT h.*
FROM Sales.SalesOrderHeader h
WHERE h.ShipMethodID = (SELECT TOP 1 [OVERNIGHT J-FAST] FROM ShipMethod.ShipMethodID)
于 2015-09-03T11:03:44.463 回答
27

我缺少常量的解决方法是向优化器提供有关值的提示。

DECLARE @Constant INT = 123;

SELECT * 
FROM [some_relation] 
WHERE [some_attribute] = @Constant
OPTION( OPTIMIZE FOR (@Constant = 123))

这告诉查询编译器在创建执行计划时将变量视为常量。不利的一面是您必须两次定义该值。

于 2012-10-04T08:31:47.867 回答
10

不,但应该使用良好的旧命名约定。

declare @MY_VALUE as int
于 2008-08-25T19:15:26.450 回答
8

T-SQL 中没有对常量的内置支持。您可以使用 SQLMenace 的方法来模拟它(尽管您永远无法确定其他人是否覆盖了该函数以返回其他内容……),或者可能编写一个包含常量的表,如此处所建议的那样。也许编写一个触发器来回滚对ConstantValue列的任何更改?

于 2008-08-25T19:16:37.523 回答
7

在使用 SQL 函数之前,请运行以下脚本以查看性能差异:

IF OBJECT_ID('fnFalse') IS NOT NULL
DROP FUNCTION fnFalse
GO

IF OBJECT_ID('fnTrue') IS NOT NULL
DROP FUNCTION fnTrue
GO

CREATE FUNCTION fnTrue() RETURNS INT WITH SCHEMABINDING
AS
BEGIN
RETURN 1
END
GO

CREATE FUNCTION fnFalse() RETURNS INT WITH SCHEMABINDING
AS
BEGIN
RETURN ~ dbo.fnTrue()
END
GO

DECLARE @TimeStart DATETIME = GETDATE()
DECLARE @Count INT = 100000
WHILE @Count > 0 BEGIN
SET @Count -= 1

DECLARE @Value BIT
SELECT @Value = dbo.fnTrue()
IF @Value = 1
    SELECT @Value = dbo.fnFalse()
END
DECLARE @TimeEnd DATETIME = GETDATE()
PRINT CAST(DATEDIFF(ms, @TimeStart, @TimeEnd) AS VARCHAR) + ' elapsed, using function'
GO

DECLARE @TimeStart DATETIME = GETDATE()
DECLARE @Count INT = 100000
DECLARE @FALSE AS BIT = 0
DECLARE @TRUE AS BIT = ~ @FALSE

WHILE @Count > 0 BEGIN
SET @Count -= 1

DECLARE @Value BIT
SELECT @Value = @TRUE
IF @Value = 1
    SELECT @Value = @FALSE
END
DECLARE @TimeEnd DATETIME = GETDATE()
PRINT CAST(DATEDIFF(ms, @TimeStart, @TimeEnd) AS VARCHAR) + ' elapsed, using local variable'
GO

DECLARE @TimeStart DATETIME = GETDATE()
DECLARE @Count INT = 100000

WHILE @Count > 0 BEGIN
SET @Count -= 1

DECLARE @Value BIT
SELECT @Value = 1
IF @Value = 1
    SELECT @Value = 0
END
DECLARE @TimeEnd DATETIME = GETDATE()
PRINT CAST(DATEDIFF(ms, @TimeStart, @TimeEnd) AS VARCHAR) + ' elapsed, using hard coded values'
GO
于 2012-12-31T00:40:05.297 回答
7

如果您有兴趣为变量中的值获取最佳执行计划,您可以使用动态 sql 代码。它使变量保持不变。

DECLARE @var varchar(100) = 'some text'
DECLARE @sql varchar(MAX)
SET @sql = 'SELECT * FROM table WHERE col = '''+@var+''''
EXEC (@sql)
于 2016-09-23T11:35:37.710 回答
5

对于枚举或简单常量,具有单行的视图具有出色的性能和编译时检查/依赖跟踪(因为它是列名)

请参阅 Jared Ko 的博客文章https://blogs.msdn.microsoft.com/sql_server_appendix_z/2013/09/16/sql-server-variables-parameters-or-literals-or-constants/

创建视图

 CREATE VIEW ShipMethods AS
 SELECT CAST(1 AS INT) AS [XRQ - TRUCK GROUND]
   ,CAST(2 AS INT) AS [ZY - EXPRESS]
   ,CAST(3 AS INT) AS [OVERSEAS - DELUXE]
  , CAST(4 AS INT) AS [OVERNIGHT J-FAST]
   ,CAST(5 AS INT) AS [CARGO TRANSPORT 5]

使用视图

SELECT h.*
FROM Sales.SalesOrderHeader 
WHERE ShipMethodID = ( select [OVERNIGHT J-FAST] from ShipMethods  )
于 2017-12-28T19:31:01.633 回答
3

好的,让我们看看

常量是不可变的值,在编译时已知并且在程序的生命周期内不会改变

这意味着您永远不能在 SQL Server 中使用常量

declare @myvalue as int
set @myvalue = 5
set @myvalue = 10--oops we just changed it

值刚刚改变

于 2008-08-25T19:16:16.820 回答
1

由于没有内置支持常量,我的解决方案非常简单。

由于不支持:

Declare Constant @supplement int = 240
SELECT price + @supplement
FROM   what_does_it_cost

我只是将其转换为

SELECT price + 240/*CONSTANT:supplement*/
FROM   what_does_it_cost

显然,这依赖于整个事物(没有尾随空格和注释的值)是唯一的。可以通过全局搜索和替换来更改它。

于 2017-12-29T16:40:13.193 回答
0

数据库文献中没有“创建常数”之类的东西。常量按原样存在,通常称为值。可以声明一个变量并为其分配一个值(常量)。从学术的角度来看:

DECLARE @two INT
SET @two = 2

这里@two 是一个变量,2 是一个值/常数。

于 2008-08-25T19:05:04.883 回答
-1

最好的答案是根据要求来自 SQLMenace,如果这是创建一个临时常量以在脚本中使用,即跨多个 GO 语句/批处理。

只需在 tempdb 中创建过程,就不会影响目标数据库。

这方面的一个实际示例是数据库创建脚本,该脚本在包含逻辑模式版本的脚本末尾写入控制值。文件顶部是一些带有更改历史记录等的注释......但实际上大多数开发人员会忘记向下滚动并更新文件底部的架构版本。

使用上面的代码允许在数据库脚本(从 SSMS 的生成脚本功能复制)创建数据库之前在顶部定义一个可见的模式版本常量,但在最后使用。这在开发人员面前就在更改历史记录和其他评论旁边,因此他们很可能会对其进行更新。

例如:

use tempdb
go
create function dbo.MySchemaVersion()
returns int
as
begin
    return 123
end
go

use master
go

-- Big long database create script with multiple batches...
print 'Creating database schema version ' + CAST(tempdb.dbo.MySchemaVersion() as NVARCHAR) + '...'
go
-- ...
go
-- ...
go
use MyDatabase
go

-- Update schema version with constant at end (not normally possible as GO puts
-- local @variables out of scope)
insert MyConfigTable values ('SchemaVersion', tempdb.dbo.MySchemaVersion())
go

-- Clean-up
use tempdb
drop function MySchemaVersion
go
于 2012-12-03T14:56:23.017 回答