ssl - Erlang SSL 前向保密

Question

我使用 Erlang Mochiweb 作为带有 SSL 的 Http 服务器。Mochiweb 使用纯 Erlang SSL 库。

如何配置 erlang ssl 以支持前向保密？有关 SSL 前向保密的更多信息：https ://en.wikipedia.org/wiki/Forward_secrecy

Answer 1

我正在使用带有 openssl 1.0.2a 的 Erlang/OTP 17（erlang 需要 openssl 用于密码，但不需要握手或协议，所以理论上它应该支持所有支持 openssl 的密码），所以它的 SSL 模块默认支持完美的前向保密。但它也默认支持一些不安全的协议或密码，如 sslv3 或 des，或弱密码，如 rc4。SSLlabs ssltest 将为您提供默认选项的 C 级。您可能想要禁用不安全的协议和密码。

而且，erlang ssl 模块默认情况下会尊重客户端的密码套件偏好。这将使一些 IE 使用 RSA 密钥交换，因为这些版本更喜欢 RSA 密钥交换而不是 ECDHE（参见：https ://www.ssllabs.com/ssltest/viewClient.html?name=IE&version=8-10&platform=Win%207 ）。您将需要{honor_cipher_order, true}使用服务器的首选项。您需要手动调整密码套件的偏好顺序以适应您的需要。默认顺序不完全按 PFS 排序。

如果您可以控制客户端（例如您自己的应用程序而不是浏览器），并且您真的只想要 PFS，您可以禁用 rsa 密钥交换。

erlang 的示例 escript 和选项是：我没有重新排序密码套件订单。

对于 mochiweb，您可以将这些选项添加到您的 ssl_opts。

#!/usr/bin/env escript

% these ciphers will got A- on ssllabs's ssltest.
% Because as mentioned above, some version's IE prefers non-PFS key exchange.
% And got A if {honor_cipher_order, true} is set.
% No manual adjusting needed to get A, because the first ciphersuite is PFS-enabled and supported by IEs.
% So you need to adjust orders to fit whatever you needed.
secure_ciphers() -> secure_ciphers(ssl:cipher_suites()). 


% It includes insecure and weak ciphers, so it should get low rank on ssltest
pfs_ciphers() -> pfs_ciphers(ssl:cipher_suites()). 

% Rank A on ssllabs' ssltest, all modern client is using perfect forward secrecy key-exchange   
% but some client without PFS support will fail to handshake.
pfs_secure_ciphers() ->  
        sets:to_list(sets:intersection(sets:from_list(secure_ciphers()), sets:from_list(pfs_ciphers()))). 

secure_ciphers([]) -> [];
secure_ciphers([{_, rc4_128, _} | T]) -> secure_ciphers(T);
secure_ciphers([{_, des_cbc, _} | T]) -> secure_ciphers(T);
secure_ciphers([{dhe_rsa, _, _} | T]) -> secure_ciphers(T);
secure_ciphers([{_, _, md5} | T]) -> secure_ciphers(T);
secure_ciphers([H | T]) -> [H | secure_ciphers(T)].


pfs_ciphers([]) -> [];
pfs_ciphers([{dhe_dss, _, _} = H | T]) -> [H | pfs_ciphers(T)];
pfs_ciphers([{dhe_rsa, _, _} = H | T]) -> [H | pfs_ciphers(T)];
pfs_ciphers([{ecdhe_ecdsa, _, _} = H | T]) -> [H | pfs_ciphers(T)];
pfs_ciphers([{ecdhe_rsa, _, _} = H | T]) -> [H | pfs_ciphers(T)];
pfs_ciphers([_ | T]) -> pfs_ciphers(T).

accept(S) ->
        {ok, Q} = ssl:transport_accept(S),
        spawn(fun() -> accept(S) end),
        ssl:ssl_accept(Q),
        receive
                Msg ->
                        io:format("~p~n", [Msg]),
                        ssl:send(Q, <<"HTTP/1.0 200 OK\r\n\r\nHello World\r\n">>),
                        ssl:close(Q)
        end.

main(_) ->
        ssl:start(),
        {ok, P} = ssl:listen(443, [{certfile, "./aa.crt"}, {keyfile, "./aa.key"}, {ciphers, pfs_secure_ciphers()}, {versions, [tlsv1, 'tlsv1.1', 'tlsv1.2']}, {dhfile, "./dh4096.pem"}]),
        accept(P),
        receive
                stop ->
                        ok
        end.