3

Inno Setup WizardImageFile（和WizardSmallImageFile）的位图看起来很糟糕，因为当 Windows 7 启用了大系统字体时，向导比平常大，但图像缩放严重错误。

有解决办法吗？

如果我在这样的地方添加自己的图片，则没有类似的问题：

BitmapImage1.AutoSize := True;
BitmapImage1.Align := alClient;
BitmapImage1.Left := 0;
BitmapImage1.Top := 0;
BitmapImage1.stretch := True;
BitmapImage1.Parent := Splash;
4

1 回答 1

6

这些是位图图像，它们自然缩放得很差。您很幸运，您自己的图像在缩放时看起来并没有那么糟糕。

您必须为常见的缩放因子准备自己的图像集。

现在常用的比例因子有 100%、125%、150% 和 200%。所以你应该有四种尺寸的图像，比如：

WizardImage 100.bmp
WizardImage 125.bmp
WizardImage 150.bmp
WizardImage 200.bmp
WizardSmallImage 100.bmp
WizardSmallImage 125.bmp
WizardSmallImage 150.bmp
WizardSmallImage 200.bmp

Inno Setup 可以自动选择自 5.6 以来图像的最佳版本。WizardImageFile只需在和中列出您的图像版本即可WizardSmallImageFile。您可以使用通配符：

[Setup]
WizardImageFile=WizardImage *.bmp
WizardImageFile=WizardSmallImage *.bmp

在旧版本的 Inno Setup 上（或者如果您需要自定义选择算法或者当您在向导中有其他自定义图像时），您必须以编程方式选择图像。

下面的例子和 Inno Setup 5.6 差不多：

[Setup]
; Use 100% images by default
WizardImageFile=WizardImage 100.bmp
WizardSmallImageFile=WizardSmallImage 100.bmp

[Files]
; Embed all other sizes to the installer
Source: "WizardImage *.bmp"; Excludes: "* 100.bmp"; Flags: dontcopy
Source: "WizardSmallImage *.bmp"; Excludes: "* 100.bmp"; Flags: dontcopy

[Code]

function GetScalingFactor: Integer;
begin
  if WizardForm.Font.PixelsPerInch >= 192 then Result := 200
    else
  if WizardForm.Font.PixelsPerInch >= 144 then Result := 150
    else
  if WizardForm.Font.PixelsPerInch >= 120 then Result := 125
    else Result := 100;
end;

procedure LoadEmbededScaledImage(Image: TBitmapImage; NameBase: string);
var
  Name: String;
  FileName: String;
begin
  Name := Format('%s %d.bmp', [NameBase, GetScalingFactor]);
  ExtractTemporaryFile(Name);
  FileName := ExpandConstant('{tmp}\' + Name);
  Image.Bitmap.LoadFromFile(FileName);
  DeleteFile(FileName);
end;

procedure InitializeWizard;
begin
  { If using larger scaling, load the correct size of images }
  if GetScalingFactor > 100 then 
  begin
    LoadEmbededScaledImage(WizardForm.WizardBitmapImage, 'WizardImage');
    LoadEmbededScaledImage(WizardForm.WizardBitmapImage2, 'WizardImage');
    LoadEmbededScaledImage(WizardForm.WizardSmallBitmapImage, 'WizardSmallImage');
  end;
end;

您可能希望对SelectDirBitmapImage、SelectGroupBitmapImage和 执行相同的操作PreparingErrorBitmapImage。

也可以看看：

于 2015-06-23T12:44:10.873 回答