4

我有一个电子表格，人们可以在其中输入项目更新，然后输入更新日期。正在发生的事情是人们忘记了他们的笔记日期。有没有办法让日期单元格自动填充当前/输入日期？

我假设 if 函数会做到这一点？

4

4 回答 4

5

如果在A列中输入了值，此事件宏会将日期放在B列中。 宏应安装在工作表代码区域中：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim A As Range, B As Range, Inte As Range, r As Range
    Set A = Range("A:A")
    Set Inte = Intersect(A, Target)
    If Inte Is Nothing Then Exit Sub
    Application.EnableEvents = False
        For Each r In Inte
            r.Offset(0, 1).Value = Date
        Next r
    Application.EnableEvents = True
End Sub

因为它是工作表代码，所以非常容易安装和自动使用：

  1. 右键单击 Excel 窗口底部附近的选项卡名称
  2. 选择查看代码 - 这将打开一个 VBE 窗口
  3. 粘贴这些东西并关闭 VBE 窗口

如果您有任何疑虑，请先在试用工作表上进行尝试。

如果您保存工作簿，宏将与它一起保存。如果您使用的是 2003 年以后的 Excel 版本，则必须将文件另存为 .xlsm 而不是 .xlsx

要删除宏：

  1. 如上所述调出 VBE 窗口
  2. 清除代码
  3. 关闭 VBE 窗口

要了解有关宏的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其正常工作！

更改代码以使用不同的列。

编辑＃1：

此版本不会覆盖B列中已经存在的材料：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim A As Range, B As Range, Inte As Range, r As Range
    Set A = Range("A:A")
    Set Inte = Intersect(A, Target)
    If Inte Is Nothing Then Exit Sub
    Application.EnableEvents = False
        For Each r In Inte
            If r.Offset(0, 1).Value = "" Then
               r.Offset(0, 1).Value = Date
            End If
        Next r
    Application.EnableEvents = True
End Sub
于 2014-10-16T18:53:37.793 回答
2

ZAT 的答案对我有用......在我将“;”s 更改为“,”s 之后。

=IF(AND(D52<>"",D52<>0),NOW(),"")

我用“现在”而不是“今天”来给我一天中的时间。

于 2015-10-27T17:30:23.460 回答
1

当相应的输入单元格（例如 D13）不为空且未填充 0 时，在所需的单元格（例如 C13）中尝试此公式以填充当前日期：

=IF(AND(D13<>"";D13<>0);TODAY();"")

然后您可以将此公式复制到后续单元格以填写该列的公式（例如col C）

于 2014-10-17T17:24:19.247 回答
1

在 A 列和 B 列中输入日期和时间，在 D 列中输入数据

Private Sub Worksheet_Change(ByVal Target As Range)
Dim A As Range, B As Range, Inte As Range, r As Range
Set A = Range("D:D")
Set Inte = Intersect(A, Target)
If Inte Is Nothing Then Exit Sub
Application.EnableEvents = False
    For Each r In Inte
        If r.Value > 0 Then
           r.Offset(0, -3).Value = Date
           r.Offset(0, -3).NumberFormat = "dd-mm-yyyy"
           r.Offset(0, -2).Value = Time
           r.Offset(0, -2).NumberFormat = "hh:mm:ss AM/PM"
        Else
           r.Offset(0, -3).Value = ""
           r.Offset(0, -2).Value = ""
        End If
    Next r
Application.EnableEvents = True
End Sub
于 2016-08-07T16:28:08.943 回答