1

完成 FParsec 教程后，我决定尝试为 SDP（会话描述协议 RFC 4366）编写解析器——至少前 3 行。SDP 在 ABNF (RFC 4234) 中指定；所以，我正在努力解决这个问题。

用户指南第 5.1 节末尾的注释指出了“您从语法叶节点的简单解析器开始，然后逐步进行，直到最终获得完整语法的解析器”。有了这个方向和斯蒂芬回答使用管道的提示，这就是我现在所拥有的：

open FParsec
open System.Net

// handy for debugging, supposedly, but I couldn't get it to work
let breakParse (p: Parser<_,_>) stream =
  p stream

// Input
let session = "v=0
o=jdoe 2890844526 2890842807 IN IP4 10.47.16.5
s=SDP Seminar
"

type Sdp = 
  { Version : System.UInt16;
    Origin : Owner;
    SessionName : string }

and Owner = 
  { Username : string
    SessionId : string
    SessionVersion : string
    NetType : NetworkType
    AddrType : AddressType
    Address : UnicastAddress }

and NetworkType = 
  | Undefined
  | Internet

and AddressType = 
  | Undefined
  | IPv4
  | IPv6

and UnicastAddress =
  | IPaddress of System.Net.IPAddress
  | FQDomainName of string
  | ExternalAddress of string

let sep : Parser<unit, unit> = skipChar '='
let getValue typeChar = skipChar typeChar .>> sep
let many1Digit : Parser<string, unit> = many1Satisfy isDigit
let many1Hex : Parser<string, unit> = many1Satisfy isHex

let nonWhitespace : Parser<string, unit> = many1Satisfy (isNoneOf @" \n\r\t") 

//proto-version = %x76 "=" 1*DIGIT CRLF
let getVersion = getValue 'v' >>. many1Digit .>> spaces |>> System.Convert.ToUInt16

//origin-field = %x6f "=" username SP sess-id SP sess-version SP
//               nettype SP addrtype SP unicast-address CRLF
// username cannot contain whitespace; i.e., only visible chars
let getUsername : Parser<string, unit> = getValue 'o' >>. nonWhitespace .>> spaces

//sess-id = 1*DIGIT
let getSessionId = many1Digit .>> spaces

//sess-version = 1*DIGIT
let getSessionVersion = many1Digit .>> spaces

let getNetType : Parser<NetworkType, unit> = 
  pstring "IN" |>> (function 
  | "IN" -> NetworkType.Internet
  | _ -> NetworkType.Undefined)
  .>> spaces

let getAddrType : Parser<AddressType, unit> = 
  anyString 3 |>> (function 
  | "IP4" -> AddressType.IPv4
  | "IP6" -> AddressType.IPv6
  | _ -> AddressType.Undefined)
  .>> spaces

let getAddress : Parser<UnicastAddress, unit> = 
    (restOfLine true) |>> (fun a -> IPAddress.Parse a |> IPaddress )

let getUserSession = pipe3 getUsername getSessionId getSessionVersion (fun u i v -> (u, i, v))
let pipeOrigin = pipe4 getUserSession getNetType getAddrType getAddress 
              (fun us n t a -> 
                let u, i, v = us
                {Username=u; SessionId=i; SessionVersion=v; NetType=n; 
                  AddrType=t; Address=a})

//session-name-field =  %x73 "=" text CRLF
let getSessionName = getValue 's' >>. restOfLine true

let threelines = pipe3 getVersion pipeOrigin getSessionName 
              (fun v o sn -> {Version=v; Origin=o; SessionName=sn})

let sessionDesc = run threelines session

这有效（除了 getAddress 不处理 FQDN 或外部地址），结果如下：

val sessionDesc : ParserResult<Sdp,unit> =
  Success: {Version = 0us;
 Origin = {Username = "jdoe";
           SessionId = "2890844526";
           SessionVersion = "2890842807";
           NetType = Internet;
           AddrType = IPv4;
           Address = IPaddress 10.47.16.5;};
 SessionName = "SDP Seminar";}

现在这是目标记录类型 Sdp。但通过一些元组将结果输入输出是一种有点复杂的方式。

我已经阅读了用户指南到第 5.4 节，但所有示例都解析为有区别的联合。Record类型是整理结果的最佳选择；或者，还有更好的方法？

4

1 回答 1

2

您可以使用这些pipe函数按顺序对行应用解析器，然后构造一条记录。（如果您需要超过 5 个临时对象，您可以轻松组合多个pipex组合器以创建pipe具有更多参数的组合器。）

前三行的解析器似乎还不完整。

于 2014-10-07T20:47:42.223 回答