-1

我编写了 2 个程序，它们都经过编译，并且都包含通过 .rc 文件添加的“STRINGTABLES”资源。

因此，我们将 App #1 称为“app1.exe”，将 App #2 称为“app2.exe”。

这是我的问题。在 app2.exe 中，我有一个如下所示的字符串表：

STRINGTABLE
{
1000, "Hello"
1001, "There"
}

当我运行 app1.exe 时，我试图通过 Win32 APIUpdateResource()函数更新存储在 app2.exe 中的资源。

我可以使用 Delphi 的LoadStr()函数从字符串表中加载字符串就好了。

我的问题是我需要了解如何使用UpdateResource()才能更改该字符串表中的字符串。因此，例如，我希望 app1.exe 将 app2.exe 的字符串表从您在上面看到的内容更改为：

STRINGTABLE
{
1000, "Thank"
1001, "You!"
}

很抱歉我没有任何源代码，但是我从头开始，似乎无法弄清楚这一点。

我正在使用 RAD Studio XE7。

如果你们需要更多继续，请直说，我会尽可能多地更新它，但就像我说的那样，我刚刚开始学习TResourceStream所有这些资源，所以我没有太多要展示的东西。我只能告诉你，我对编程并不陌生。我很快就掌握了东西。我已经创建了一个THandleapp1.exe 来查看 app2.exe 的资源。我可以向它添加东西，但似乎当我尝试从一个或组件添加String数据时，它在 app2.exe 的资源中显示为一些奇怪的奇怪中文字母。所以我想知道如何格式化这些字符串，以便它们正确显示在资源和内容中。TEditTMemo

为了更清楚地说明这一点，当我运行 app1.exe 并尝试将字符串输入"Hello"到 app2.exe 的字符串表中时，它给了我这个：

00230BF8  00 00 00 00                                       ••••

任何线索为什么？

我正在使用一个名为“Resource Hacker”的应用程序在运行程序后检查资源。

4

1 回答 1

7

字符串表资源存储在 16 个块中，每个项目都写有一个字大小的长度标记，然后是 UTF-16 编码字符。如果块中的项目没有在原始 RC 文件中明确定义，那么它仍然存在于编译资源中，但长度为 0。

因此，假设您已仔细选择您的 ID 与 16 个相同的组。我将坚持使用您提供的 ID，并假设您要更新同一目录中名为 TestLib.dll 的 DLL作为EXE；我还将假设我自己的语言环境（英式英语） - 您需要根据需要更改MAKELANGID参数：

const
  LibName = 'TestLib.dll';
  ID_FIRST  = 1000;
  ID_SECOND = 1001;

function StringIDToGroupID(ID: UINT): UINT; inline;
begin
  Result := (ID shr 4) + 1;
end;

procedure UpdateStrings(const NewFirst, NewSecond: string);
var
  Handle: THandle;
  GroupID: UINT;
  Stream: TCustomMemoryStream;
  GroupStrings: array[0..15] of string;
  StrLen: Word;
  I: Integer;
begin
  GroupID := StringIDToGroupID(ID_FIRST);
  //get existing data...
  Handle := LoadLibraryEx(LibName, 0, LOAD_LIBRARY_AS_DATAFILE);
  if Handle = 0 then RaiseLastOSError;
  try
    Stream := TResourceStream.CreateFromID(Handle, GroupID, RT_STRING);
    try
      for I := Low(GroupStrings) to High(GroupStrings) do
      begin
        Stream.ReadBufferData(StrLen);
        SetLength(GroupStrings[I], StrLen);
        Stream.ReadBuffer(PChar(GroupStrings[I])^, StrLen * SizeOf(Char));
      end;
    finally
      Stream.Free;
    end;
  finally
    FreeLibrary(Handle);
  end;
  //update the strings we're interested in...
  GroupStrings[ID_FIRST mod Length(GroupStrings)] := NewFirst;
  GroupStrings[ID_SECOND mod Length(GroupStrings)] := NewSecond;
  Stream := TMemoryStream.Create;
  try
    for I := Low(GroupStrings) to High(GroupStrings) do
    begin
      StrLen := Length(GroupStrings[I]);
      Stream.WriteData(StrLen);
      Stream.WriteBuffer(PChar(GroupStrings[I])^, StrLen * SizeOf(Char));
    end;
    //update DLL...
    Handle := BeginUpdateResource(LibName, False);
    if Handle = 0 then RaiseLastOSError;
    try
      UpdateResource(Handle, RT_STRING, PChar(GroupID),
        MAKELANGID(LANG_ENGLISH, SUBLANG_ENGLISH_UK), Stream.Memory, Stream.Size);
    finally
      EndUpdateResource(Handle, False);
    end;
  finally
    Stream.Free;
  end;
end;
于 2014-09-28T19:56:36.013 回答