1

我正在解析 happstack 中的表单，但我不知道在服务器上收集表单变量的更简洁的方法。有谁知道是否有任何技巧可以减少此处所需的代码量？

 formHandler = do
    method POST
    delA1       <- look "address-01-delivery"
    delA2       <- look "address-02-delivery"
    delSuburb   <- look "suburb-delivery"
    delPostcode <- look "postcode-delivery"
    delState    <- look "state-delivery"
    delCountry  <- look "country-delivery"

    bilA1       <- look "address-01-billing"
    bilA2       <- look "address-02-billing"
    bilSuburb   <- look "suburb-billing"
    bilPostcode <- look "postcode-billing"
    bilState    <- look "state-billing"
    bilCountry  <- look "country-billing"
4

1 回答 1

1

前言：这显然不会减少您在上面发布的代码量，但从长远来看，它可能会使事情更易于维护，因为它提供了执行验证的一致方式并允许您处理强类型对象而不是大型对象文本值的数量。

如果您要进行任何数量的表单处理，我建议您使用表单库。我个人使用过消化功能，发现使用起来很愉快。同样，它带有一个 Happstack 后端，这使得 Happstack 集成非常简单。

这可能比您愿意投资的要多，但这里是您的表单代码使用消化函子的样子的示例。我没有尝试编译任何这些，所以它可能会或可能不会起作用，但希望它提供了总体思路。

{-# LANGUAGE OverloadedStrings #-}

module Forms where

import Control.Applicative ((<$>), (<*>))
import Data.Text (Text)
import qualified Data.Text as T
import Happstack.Server
import Text.Digestive


data AddressState 
  = Alabama
  | Alaska
  | Arkansas
  -- ...
  deriving (Enum, Eq, Read)

data Country
  = Canada
  | Mexico
  | UnitedStates
  -- ...
  deriving (Enum, Eq, Read)

data Address = Address
  { street1  :: Text
  , street2  :: Maybe Text
  , suburb   :: Maybe Text
  , postcode :: Int
  , state    :: AddressState
  , country  :: Country
  }

data ShippingForm = ShippingForm
  { deliveryAddress :: Address
  , billingAddress  :: Address
  }

addressForm :: (Monad m) => Form Text m Address
addressForm = Address
  <$> "street1"  .: nonEmptyText (text Nothing)
  <*> "street2"  .: optionalText Nothing
  <*> "suburb"   .: optionalText Nothing
  <*> "postcode" .: stringRead "Please enter a valid postcode" Nothing
  <*> "state"    .: choice mkChoices Nothing
  <*> "country"  .: choice mkChoices Nothing
  where
    nonEmptyText = check "Cannot be empty" (not . T.null)
    mkChoices = [(x, T.pack (show x)) | x <- [minBound .. maxBound]]

shippingForm :: (Monad m) => Form Text m ShippingForm
shippingForm = ShippingForm
  <$> "delivery" .: addressForm
  <*> "billing"  .: addressForm

formHandler :: ServerPart Response
formHandler = do
  method POST
  decodeBody $ defaultBodyPolicy "/tmp" 4096 4096 4096
  res <- runForm "shipping" shippingForm
  case res of
    (view, Nothing) -> do
      -- setup your view
      ok $ toResponse () -- <-- replace this with your view code
    (_, Just formData) -> do
      -- here, formData is a fully valid `ShippingForm`
      let delStreet1 = (street1 . deliveryAddress) formData
      -- do whatever you need to with this data (ie: persist it to a database, etc)
      ok $ toResponse ()

有关消化函子的一些好读物，您可以查看以下链接：

消化函子教程

ocharles 的博文

于 2014-09-26T15:15:27.973 回答