9

使用选项测试StrUtils.SearchBuf[soWholeWord,soDown]时，出现了一些意外结果。

program Project1;

Uses
  SysUtils,StrUtils;

function WordFound(aString,searchString: String): Boolean;
begin
  Result := SearchBuf(PChar(aString),Length(aString), 0, 0, searchString, 
    [soWholeWord,soDown]) <> nil;
end;

Procedure Test(aString,searchString: String);
begin
  WriteLn('"',searchString,'" in "',aString,'"',#9,' : ',
    WordFound(aString,searchString));
end;

begin
  Test('Delphi','Delphi');   // True
  Test('Delphi ','Delphi');  // True
  Test(' Delphi','Delphi');  // False
  Test(' Delphi ','Delphi'); // False
  ReadLn;
end.

为什么' Delphi'不' Delphi '被认为是一个完整的词？

反向搜索呢？

function WordFoundRev(aString,searchString: String): Boolean;
begin
  Result := SearchBuf(PChar(aString),Length(aString),Length(aString)-1,0,searchString, 
    [soWholeWord]) <> nil;
end;

Procedure TestRev(aString,searchString: String);
begin
  WriteLn('"',searchString,'" in "',aString,'"',#9,' : ',
    WordFoundRev(aString,searchString));
end;

begin
  TestRev('Delphi','Delphi');   // False
  TestRev('Delphi ','Delphi');  // True
  TestRev(' Delphi','Delphi');  // False
  TestRev(' Delphi ','Delphi'); // True
  ReadLn;
end.

我完全不明白这一点。除了功能是错误的。

XE7、XE6 和 XE 的结果相同。

更新

QC127635 StrUtils.SearchBuf 使用 [soWholeWord] 选项失败

4

1 回答 1

6

对我来说它看起来像一个错误。这是执行搜索的代码：

while SearchCount > 0 do
begin
  if (soWholeWord in Options) and (Result <> @Buf[SelStart]) then
    if not FindNextWordStart(Result) then Break;
  I := 0;
  while (CharMap[(Result[I])] = (SearchString[I+1])) do
  begin
    Inc(I);
    if I >= Length(SearchString) then
    begin
      if (not (soWholeWord in Options)) or
         (SearchCount = 0) or
         ((Byte(Result[I])) in WordDelimiters) then
        Exit;
      Break;
    end;
  end;
  Inc(Result, Direction);
  Dec(SearchCount);
end;

每次while循环我们检查是否soWholeWord在选项中，然后前进到下一个单词的开头。但我们只有在

Result <> @Buf[SelStart]

现在，Result是当前指向缓冲区的指针，是匹配的候选对象。所以这个测试检查我们是否在被搜索字符串的开头。

这个测试的意思是，如果搜索的字符串以非字母数字文本开头，我们不能将非字母数字文本推进到第一个单词的开头。

现在，您可能决定删除测试

Result <> @Buf[SelStart]

但是如果你这样做，你会发现如果它位于字符串的开头，你将不再匹配该单词。所以你只会以不同的方式失败。处理这个问题的正确方法是确保FindNextWordStart如果我们位于字符串的开头，并且那里的文本是字母数字，则它不会前进。

我的猜测是原作者写了这样的代码：

if (soWholeWord in Options) then
  if not FindNextWordStart(Result) then Break;

然后他们发现字符串开头的单词不匹配，并将代码更改为：

if (soWholeWord in Options) and (Result <> @Buf[SelStart]) then
  if not FindNextWordStart(Result) then Break;

如果字符串以非字母数字文本开头，没有人测试会发生什么。

这样的事情似乎可以完成工作：

if (soWholeWord in Options) then
  if (Result <> @Buf[SelStart]) or not Result^.IsLetterOrDigit then
    if not FindNextWordStart(Result) then Break;
于 2014-09-16T20:49:00.580 回答