perl - 如何判断 Log4perl 在运行期间是否发出任何警告？

Question

我一直在许多脚本中广泛使用Log4perl。如果已记录任何WARN或消息，我想扩充这些脚本以设置错误代码。ERROR根据现有文档，我找不到任何明显的方法来做到这一点。

我想避免对我现有的脚本进行强力重写以添加对每条消息WARN或ERROR日志消息的检查；如果可能的话，我宁愿在脚本退出之前处理它，比如这个伪代码：

if $log->has_warnings_or_errors then
  exit 1
else
  exit 0

有什么简单的方法可以调用 Log4Perl 来确定当前记录器是否有某些级别的问题消息？

Answer 1

使用附加程序。

MyCounter.pm:

package MyCounter;

use warnings;
use strict;

use Log::Log4perl::Level;

sub new {
  my($class,%arg) = @_;
  bless {} => $class;
}

sub log {
  my($self,%arg) = @_;
  ++$self->{ $arg{log4p_level} };
}

sub howmany {
  my($self,@which) = @_;
  my $total = 0;
  $total += ($self->{$_} || 0) for @which;
  $total;
}

1;

我的程序：

#! /usr/bin/perl

use warnings;
use strict;

use Log::Log4perl;

my $conf = q(
  log4perl.category.MyLogger = INFO, Screen

  log4perl.appender.Screen = Log::Log4perl::Appender::Screen
  log4perl.appender.Screen.layout = Log::Log4perl::Layout::SimpleLayout
);

Log::Log4perl->init(\$conf);

my $l = Log::Log4perl->get_logger("MyLogger");

my $counter = Log::Log4perl::Appender->new("MyCounter");
$l->add_appender($counter);

$l->warn("warning");
$l->info("info");
$l->error("incorrect");
$l->fatal("really bad, man");

print $counter->howmany(qw/ WARN ERROR FATAL /), "\n";

exit ($counter->howmany(qw/ WARN ERROR FATAL /) ? 1 : 0);

输出：

$ ./myprog
WARN - 警告
信息 - 信息
错误 - 不正确
致命 - 真的很糟糕，伙计
3
$回声$？
1

注释掉...->warn, ...->error, 和...->fatal行以获得

$ ./myprog
信息 - 信息
0
$回声$？
0

Answer 2

您可以使用包装器并编写 custom fatal，error以及warn增加计数器的方法和返回该计数器值的访问器。