2

我在这里阅读 XSLT 3.0 的 W3C 文档。我想知道如何使用这些元素：

(1) xsl:decimal-format
(2) xsl:stream
(3) xsl:accumulator
(4) xsl:accumulator-rule
(5) xsl:fork

显然，这些是一些较少使用的元素。由于此处给出的示例有限，因此此处提供的答案将使未来的 XSLT 学习者受益。有人可以演示如何使用它们吗？

我知道要回答的问题很多。所以我会赞成任何正确的部分答案，希望它对其他人有用。

4

2 回答 2

5

xsl:decimal-format自 1.0 版以来一直在规范中；您引用的其他元素是 3.0 版中的新元素，并且都与流相关联（即“动态”处理源文档的能力，而无需将整个树加载到内存中）。

<xsl:stream href="in.xml">
   ...do something...
</xsl:stream>

具有基本相同的效果

<xsl:for-each select="doc('in.xml')">
   ...do something...
</xsl:for-each>

除了“做某事”是流式传输的（这意味着它必须符合流式传输规则）。例如，如果你想找出大量员工的平均工资，你可以这样做

<xsl:stream href="in.xml">
   <result><xsl:value-of select="avg(//employee/@salary)"/></result>
</xsl:stream>

如果您想在输入文档的单个流式传输过程中计算最低和最高工资怎么办？xsl:fork 和 accumulators 都为这个问题提供了解决方案。xsl:fork 允许您指定两个或多个在同一通道中发生的计算，有效地并行：

<xsl:stream href="in.xml">
   <result>
     <xsl:fork>
        <xsl:sequence>
           <min><xsl:value-of select="min(//employee/@salary)"/></min>
        </xsl:sequence>
        <xsl:sequence>
           <max><xsl:value-of select="max(//employee/@salary)"/></max>
        </xsl:sequence>
     </xsl:fork>
   </result>
</xsl:stream>

xsl:accumulator 允许您定义有效发生的处理作为阅读文档的副作用：

<xsl:accumulator name="min-salary" initial-value="10000000">
  <xsl:accumulator-rule match="employee" 
      select="if (@salary lt $value) then @salary else $value"/>
</xsl:accumulator>

然后您可以在处理过程中的任何时候通过调用读取最低工资accumulator-before('min-salary')。

于 2014-09-14T15:22:29.267 回答
2

<xsl:decimal-format>
在这里找到了一个很好的例子：MSDN xsl:decimal-format

简化示例：<xsl:decimal-format>在 XSL 中 声明

<xsl:decimal-format name="example" decimal-separator="." grouping-separator=","  
 infinity="INFINITY" minus-sign="-" NaN="Not a Number" percent="%"
 per-mille="m" zero-digit="0" digit="#" pattern-separator=";" />

与它一起使用<xsl:format-number> 

<xsl:value-of select="format-number(1 div 0, '###,###.00', 'example')"/>

输出： INFINITY
参考：http ://www.w3.org/TR/2013/WD-xslt-30-20131212/#dt-decimal-format 在http://exselt.net/demo
上测试的完整工作演示： 

<?xml version="1.0"?>
<?xml-stylesheet type="text/xsl" href="decimalformat.xsl"?>
<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
<xsl:output method="html"/>   
<xsl:decimal-format name="example" decimal-separator="." grouping-separator=","
  infinity="INFINITY" minus-sign="-" NaN="Not a Number" percent="%"
  per-mille="m" zero-digit="0" digit="#" pattern-separator=";" /> 
<xsl:template match="/">
  <html>
    <head></head>
    <body>
        <xsl:value-of select="format-number(1 div 0, '###,###.00', 'example')"/>  
    </body>
  </html>
</xsl:template>

于 2014-09-14T10:47:30.237 回答