0

我有一个创建 html 文件并使用 textedit 打开它们的applescript：

try
    tell application "Finder" to set save_folder to (target of window 1) as alias
on error
    set save_folder to path to desktop
end try

set textFile to (choose file name with prompt "Enter file name:" default location save_folder default name "Comment.html") as text
if textFile does not end with ".html" then set textFile to textFile & ".html"
do shell script "touch " & quoted form of POSIX path of textFile
tell application "Finder"
    set file type of (textFile as alias) to "html"
    set creator type of (textFile as alias) to "sfri"
end tell
tell application "TextEdit"
    open file textFile
    activate
end tell

该文件以锁定状态打开，这很痛苦。但是，如果我将文件类型和创建者设置为 TEXT 和 ttxt（TextEdit 的标识符），那么一切都很好。我讨厌为了编辑html文件而不得不授予对textedit的root访问权限，但我想这就是需要的吗？我想我可以切换到另一个文本编辑器，但我有一个问题，为什么 TextEdit 会以这种方式处理 html 文件？

4

1 回答 1

2

要打开没有锁定的空 HTML 文件：

第一个解决方案：检查TextEdit首选项Display HTML files as HTML code instead of formatted text中的“”按钮。但是你必须在文档中编写 HTML 代码

--

第二种解决方案：为空的 HTML 文件编写有效的 HTML 代码，如下所示：

set base to "<!DOCTYPE html PUBLIC \"-//W3C//DTD HTML 4.01//EN\" \"http://www.w3.org/TR/html4/strict.dtd\"><html><head>
<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\"><meta http-equiv=\"Content-Style-Type\" content=\"text/css\">
<title></title><meta name=\"Generator\" content=\"Cocoa HTML Writer\"><meta name=\"CocoaVersion\" content=\"1265.21\">
<style type=\"text/css\"></style></head><body></body></HTML>"

try
    tell application "Finder" to set save_folder to (target of window 1) as alias
on error
    set save_folder to path to desktop
end try
set textFile to (choose file name with prompt "Enter file name:" default location save_folder default name "Comment.html") as text
if textFile does not end with ".html" then set textFile to textFile & ".html"
do shell script "printf  " & (quoted form of base) & " > " & quoted form of POSIX path of textFile
tell application "TextEdit"
    open file textFile
    activate
end tell
于 2014-09-25T02:51:34.170 回答