12

所以我们有：

import Control.Monad.Writer.Strict

type M a = Writer (Map Key Val) a

对于一些Key和Val。

只要我们不查看收集的输出，一切正常：

report comp = do
  let (a,w) = runWriter comp
  putStrLn a

但是，如果我们要检查w，我们会得到堆栈溢出。

 report comp = do
   let (a,w) = runWriter comp
   guard (not $ null w) $ do -- forcing w causes a stack overflow
     reportOutputs w
   putStrLn a

我认为原因是因为(>>=)forWriter 被定义为：

m >>= k  = WriterT $ do
    (a, w)  <- runWriterT m
    (b, w') <- runWriterT (k a)
    return (b, w `mappend` w')

如果我有一个大的Writer a计算，它会建立一个很长的 mappends 序列：w <> (w' <> (w'' <> ...))在这种情况下，Map.union这在地图的脊椎中是严格的。因此，如果我建立了大量的联合，则必须在我强制使堆栈溢出的 Map 时立即评估整个事情。

我们想要的是尽早执行联合。我们想要一个更严格的 Strict.Writer：

m >>= k = WriterT $ do
    (a, w) <- runWriterT m
    (b, w') <- runWriterT (k a)
    let w'' = w `mappend` w'
    w'' `seq` return (b, w'')

所以我的问题是：这是否存在于某些“标准”库中？如果不是，为什么不呢？

4

1 回答 1

16

您的问题的直接答案是：不，没有提供此功能的标准库。此外，您提出的版本仍然会泄漏。我知道的唯一不泄漏的版本是WriterT使用严格的StateT. 我在 Haskell 库邮件列表中写了一封非常详细的电子邮件，比较了几种实现的严格性和性能。长话短说：WriterT以严格的方式实现StateT不仅可以消除空间泄漏，还可以生成非常高效的代码。

这是有效的实现：

newtype WriterT w m a = WriterT { unWriterT :: w -> m (a, w) }

instance (Monad m, Monoid w) => Monad (WriterT w m) where
    return a = WriterT $ \w -> return (a, w)
    m >>= f  = WriterT $ \w -> do
        (a, w') <- unWriterT m w
        unWriterT (f a) w'

runWriterT :: (Monoid w) => WriterT w m a -> m (a, w)
runWriterT m = unWriterT m mempty

tell :: (Monad m, Monoid w) => w -> WriterT w m ()
tell w = WriterT $ \w' ->
    let wt = w `mappend` w'
     in wt `seq` return ((), w `mappend` w')

我希望transformers在某个时候看到这一点，但有一些小问题需要解决（例如，模块名称应该是什么）。

于 2014-09-09T17:19:23.497 回答