perl - 从超类访问 __DATA__

Question

我有一个名为 Response 的超类：

package Response;

use strict;
use warnings;

use HTML::Template;

sub response {
    my ( $class, $request ) = @_;
    return $request->new_response( $class->status, $class->headers, $class->body );
}

sub body {
    my $class = shift;
    my $template = HTML::Template->new( 'filehandle' => eval("$class::DATA") );
    return $template->output() . $class;
}

sub status {
    return 200;
}

sub headers {
    return [ 'Content-Type' => 'text/html' ];
}

1;

__DATA__
Default content

和一个名为 URIError 的子类：

package URIError;

use strict;
use warnings;

use Response;
our @ISA = qw(Response);

1;

__DATA__
Invalid URI

当调用 URIError->response 时，行

my $template = HTML::Template->new( 'filehandle' => eval("$class::DATA") );

在 Response 类中，不会从 URIError 类中获取DATA部分内容。

实现这一点的语法是什么？

Answer 1

如果您更改这样的body方法，您的代码将起作用。不需要eval: 你所要做的就是禁用strict 'refs'和取消引用字符串"${class}::DATA"

sub body {
   my $class = shift;

   my $data_fh = do {
      no strict 'refs';
      *{"${class}::DATA"};
   };

   my $template = HTML::Template->new( filehandle => $data_fh );

   $template->output . $class;
}