4

我需要删除给定文件夹下的所有内容（文件和文件夹）。问题是该文件夹中有数百万个文件和文件夹。所以我不想一次性加载所有文件名。

逻辑应该是这样的：

  • 迭代文件夹而不加载所有内容
  • 获取文件或文件夹
  • 删除它 （详细说明文件或文件夹“X”已被删除）
  • 去下一个

我正在尝试这样的事情：

sub main(){
  my ($rc, $help, $debug, $root)   = ();
  $rc = GetOptions ( "HELP"           => \$help,
                     "DEBUG"          => \$debug,
                     "ROOT=s"         => \$root);

  die "Bad command line options\n$usage\n" unless ($rc);
  if ($help) { print $usage; exit (0); }

  if ($debug) {
      warn "\nProceeding to execution with following parameters: \n";
      warn "===============================================================\n";
      warn "ROOT = $root\n";

  } # write debug information to STDERR

  print "\n Starting to delete...\n";  

  die "usage: $0 dir ..\n" unless $root;
  *name = *File::Find::name;
  find \&verbose, @ARGV;

}

sub verbose {
    if (!-l && -d _) {
        print "rmdir $name\n";
    } else {
        print "unlink $name\n";
    }
}

main();

它工作正常，但每当“查找”读取大文件夹时，应用程序就会卡住，我可以看到 Perl 的系统内存增加直到超时。为什么？它是否试图一次性加载所有文件？

谢谢你的帮助。

4

7 回答 7

7

File::Path中的remove_tree函数可以可移植且详细地删除目录层次结构，如果需要，保留顶层目录。

use strict;
use warnings;
use File::Path qw(remove_tree);

my $dir = '/tmp/dir';
remove_tree($dir, {verbose => 1, keep_root => 1});

在 5.10 之前，使用File::Pathrmtree中的函数。如果您仍然想要顶级目录，您可以再次mkdir它。

use File::Path;

my $dir = '/tmp/dir';
rmtree($dir, 1);  # 1 means verbose
mkdir $dir;
于 2010-04-02T17:38:52.077 回答
6

有什么问题：

`rm -rf $folder`; // ??
于 2010-04-02T16:59:39.553 回答
6

perlfaq指出了遍历目录的艰巨File::Find工作，但工作并不难（假设您的目录树没有命名管道、块设备等）：

sub traverse_directory {
    my $dir = shift;
    opendir my $dh, $dir;
    while (my $file = readdir($dh)) {
        next if $file eq "." || $file eq "..";
        if (-d "$dir/$file") {
            &traverse_directory("$dir/$file");
        } elsif (-f "$dir/$file") {
            # $dir/$file is a regular file
            # Do something with it, for example:
            print "Removing $dir/$file\n";
            unlink "$dir/$file" or warn "unlink $dir/$file failed: $!\n";
        } else {
            warn "$dir/$file is not a directory or regular file. Ignoring ...\n";
        }
    }
    closedir $dh;
    # $dir might be empty at this point. If you want to delete it:
    if (rmdir $dir) {
        print "Removed $dir/\n";
    } else {
        warn "rmdir $dir failed: $!\n";
    }
}

将您自己的代码替换为对文件或（可能）空目录执行某些操作，并在您要处理的树的根目录上调用此函数一次。查找 , , , 的含义，如果opendir/closedir您以前没有遇到过。readdir-d-f

于 2010-04-02T19:15:34.777 回答
4

可以File::Find用来系统地遍历目录，删除其下的文件和目录。

于 2010-04-02T17:01:07.387 回答
2

好的，我放弃并使用了 Perl 内置函数，但你应该使用我完全忘记的File::Path::rmtree ：

#!/usr/bin/perl

use strict; use warnings;
use Cwd;
use File::Find;

my ($clean) = @ARGV;
die "specify directory to clean\n" unless defined $clean;

my $current_dir = getcwd;
chdir $clean
    or die "Cannot chdir to '$clean': $!\n";

finddepth(\&wanted => '.');

chdir $current_dir
    or die "Cannot chdir back to '$current_dir':$!\n";

sub wanted {
    return if /^[.][.]?\z/;
    warn "$File::Find::name\n";
    if ( -f ) {
        unlink or die "Cannot delete '$File::Find::name': $!\n";
    }
    elsif ( -d _ ) {
        rmdir or die "Cannot remove directory '$File::Find::name': $!\n";
    }
    return;
}
于 2010-04-02T17:16:17.917 回答
1

下载适用于windows的unix工具，然后你就可以做rm -rv任何事情了。

Perl 对于很多用途来说都是一个很棒的工具，但这个工具似乎最好由专门的工具来完成。

于 2010-04-02T19:44:31.040 回答
0

这是一种便宜的“跨平台”方法：

use Carp    qw<carp croak>;
use English qw<$OS_NAME>;
use File::Spec;  

my %deltree_op = ( nix => 'rm -rf %s', win => 'rmdir /S %s' );

my %group_for
    = ( ( map { $_ => 'nix' } qw<linux UNIX SunOS> )
      , ( map { $_ => 'win' } qw<MSWin32 WinNT>    )
      );

my $group_name = $group_for{$OS_NAME};
sub chop_tree { 
   my $full_path = shift;
   carp( "No directory $full_path exists! We're done." ) unless -e $full_path;
   croak( "No implementation for $OS_NAME!" ) unless $group_name;
   my $format = $deltree_op{$group_name};
   croak( "Could not find command format for group $group_name" ) unless $format;
   my $command = sprintf( $format, File::Spec->canonpath( $full_path ));
   qx{$command};
}
于 2010-04-02T22:38:57.093 回答