0

我正在尝试处理我的 XML 中的电话号码和传真号码元素的空间问题。

元素是：

<PhoneNumber>0870 6071352</PhoneNumber>
<FaxNumber>01722 422301</FaxNumber>

但它们也可以是：

0870 6071352

所以我需要删除前导和尾随空格，保留任何数字之间的空格，并使用前导空格将结果格式化为固定长度的 71 个字符。

所以我正在尝试编写一个命名模板，该模板将删除空格，然后用前导空格填充输出到固定长度的 71 个字符。

这是我定义的模板，但它没有编译 - 我收到一个错误Expression expected <-我找不到丢失或错误的地方

<!-- format the phone number with no spaces and output to 71 characters with leading spaces -->
<xsl:template name="FormattedPhoneFaxNumber">
    <xsl:param name="text"/>
    <xsl:choose>
      <xsl:when test="contains($text,' ')">
        <xsl:value-of select="substring-before($text,' ')"/>
        <xsl:value-of select=""/>
        <xsl:call-template name="FormattedPhoneFaxNumber">
          <xsl:with-param name="text" select="substring-after($text,' ')"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="substring(concat('                                                                       ', $text), 1, 71)"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

谁能告诉我哪里出错了？

我需要这样做的原因是因为我必须处理元素为空、具有前导或尾随空格以及值或仅值，并且我们需要输出两个带前导空格的字段，最大长度为 71人物。

4

1 回答 1

2

删除行：

<xsl:value-of select=""/>

该select属性应该是 XPath 表达式，空字符串不是有效的表达式。

但是您实际上根本不需要递归模板，如果您想从字符串中删除空格，您可以使用 来完成translate(theString, ' ', '')，并且您可能需要添加 anormalize-space来处理其他空白字符，如制表符。例如，下面的样式表

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="text" />

  <xsl:template name="FormattedPhoneFaxNumber">
      <xsl:param name="text"/>
      <xsl:variable name="noSpaces" select="translate(normalize-space($text), ' ', '')" />
      <!-- using fewer spaces for this example, but in your real case use 71 -->
      <xsl:value-of select="substring(concat('                            ',
          $noSpaces), string-length($noSpaces) + 1)"/>
  </xsl:template>

  <xsl:template match="/">
    <xsl:for-each select="*/*">
      <xsl:text>>>></xsl:text>
      <xsl:call-template name="FormattedPhoneFaxNumber">
        <xsl:with-param name="text" select="." />
      </xsl:call-template>
      <xsl:text>&lt;&lt;&lt;&#10;</xsl:text>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

在以下 XML 文档上运行时

<root>
  <num>   </num>
  <num>0123  456 7890   </num>
  <num>&#9;212-345 6789</num><!-- &#9; is a tab character -->
  <num/>
</root>

产生正确的结果

>>>                            <<<
>>>                 01234567890<<<
>>>                 212-3456789<<<
>>>                            <<<

特别是空元素会产生正确长度的完全空白字符串。

于 2014-09-04T16:09:18.770 回答