5

继之前关于提取第 n 个正则表达式匹配的问题之后，我现在需要替换匹配项（如果找到）。

我认为我可以定义提取子例程并使用/e修饰符在替换中调用它。我显然错了（诚然，我遇到了XY 问题）。

use strict;
use warnings;

sub extract_quoted { # à la codaddict

        my ($string, $index) = @_;
        while($string =~ /'(.*?)'/g) {
                $index--;
                return $1 if(! $index);
        }
        return;
}

my $string = "'How can I','use' 'PERL','to process this' 'line'";

extract_quoted ( $string, 3 );
$string =~ s/&extract_quoted($string,2)/'Perl'/e;

print $string; # Prints 'How can I','use' 'PERL','to process this' 'line'

当然，这种技术还有许多其他问题：

  • 如果在不同的位置有相同的匹配怎么办？
  • 如果找不到匹配项怎么办？

鉴于这种情况，我想知道这可以通过什么方式实现。

4

5 回答 5

4

编辑： leonbloy 首先提出了这个解决方案。如果您想投票，请先投票给 leonbloy。

受到 leonbloy （早期）回答的启发：

$line = "'How can I','use' 'PERL' 'to process this';'line'";
$n = 3;
$replacement = "Perl";

print "Old line: $line\n";
$z = 0;
$line =~ s/'(.*?)'/++$z==$n ? "'$replacement'" : "'$1'"/ge;
print "New line: $line\n";

旧行：'How can I','use' 'PERL' 'to process this';'line'
新行：'How can I','use' 'Perl' 'to process this';'line'
于 2010-03-31T19:20:54.830 回答
3

或者你可以这样做

use strict;
use warnings;

my $string = "'How can I','use' .... 'perl','to process this' 'line'";

my $cont =0;
sub replacen { # auxiliar function: replaces string if incremented counter equals $index
        my ($index,$original,$replacement) = @_;
        $cont++;
        return $cont == $index ? $replacement: $original;
}

#replace the $index n'th match (1-based counting) from $string by $rep
sub replace_quoted {
        my ($string, $index,$replacement) = @_;
        $cont = 0; # initialize match counter
        $string =~ s/'(.*?)'/replacen($index,$1,$replacement)/eg;
        return $string;
}

my $result = replace_quoted ( $string, 3 ,"PERL");
print "RESULT: $result\n";

“全局” $cont 变量有点难看，可以抛光，但你明白了。

更新：更紧凑的版本：

use strict;
my $string = "'How can I','use' .... 'perl','to process this' 'line'";

#replace the $index n'th match (1-based counting) from $string by $replacement
sub replace_quoted {
        my ($string, $index,$replacement) = @_;
        my $cont = 0; # initialize match counter
        $string =~ s/'(.*?)'/$cont++ == $index ? $replacement : $1/eg;
        return $string;
}

my $result = replace_quoted ( $string, 3 ,"PERL");
print "RESULT: $result\n";
于 2010-03-31T19:26:32.660 回答
0

如果正则表达式没有比你所拥有的复杂太多，你可以在 a 后面split加上一个 edit 和 a join：

$line = "'How can I','use' 'PERL','to process this' 'line'";

$n = 3;
$new_text = "'Perl'";
@f = split /('.*?')/, $line;
# odd fields of @f contain regex matches
# even fields contain the text between matches
$f[2*$n-1] = $new_text;
$new_line = join '', @f;
于 2010-03-31T19:21:19.727 回答
0

请参阅perldoc perlvar：

use strict; use warnings;

use Test::More tests => 5;

my %src = (
    q{'I want to' 'extract the word' 'PERL','from this string'}
    => q{'I want to' 'extract the word' 'Perl','from this string'},
    q{'What about', 'getting','PERL','from','here','?'}
    => q{'What about', 'getting','Perl','from','here','?'},
    q{'How can I','use' 'PERL','to process this' 'line'}
    => q{'How can I','use' 'Perl','to process this' 'line'},
    q{Invalid} => q{Invalid},
    q{'Another invalid string'} => q{'Another invalid string'}
);

while ( my ($src, $target) = each %src ) {
    ok($target eq subst_n($src, 3, 'Perl'), $src)
}

sub subst_n {
    my ($src, $index, $replacement) = @_;
    return $src unless $index > 0;
    while ( $src =~ /'.*?'/g ) {
        -- $index or return join(q{'},
            substr($src, 0, $-[0]),
            $replacement,
            substr($src, $+[0])
        );
    }
    return $src;
}

输出：

C:\Temp> 密码
1..5
ok 1 - '另一个无效字符串'
ok 2 - 'How can I','use' 'PERL','to process this' 'line'
好的 3 - 无效
好的 4 - '怎么样'，'得到'，'PERL'，'来自'，'这里'，'？
ok 5 - 'I want to' 'extract the word' 'PERL','from this string'

当然，您需要决定如果$index通过了无效或未找到所需的匹配会发生什么。我只是在上面的代码中返回原始字符串。

于 2010-03-31T21:26:10.727 回答
0

修改一个较早问题的答案，匹配n -1 次，然后替换下一个。记忆模式使可怜的 Perl 不必一遍又一遍地重新编译相同的模式。

my $_quoted = qr/'[^']+'/; # ' fix Stack Overflow highlighting
my %_cache;
sub replace_nth_quoted { 
  my($string,$index,$replace) = @_;
  my $pat = $_cache{$index} ||=
    qr/ ^
        (                    # $1
          (?:.*?$_quoted.*?) # match quoted substrings...
            {@{[$index-1]}}  # $index-1 times
        )
        $_quoted             # the ${index}th match
      /x;

  $string =~ s/$pat/$1$replace/;
  $string;
}

例如

my $string = "'How can I','use' 'PERL','to process this' 'line'";
print replace_nth_quoted($string, 3, "'Perl'"), "\n";

输出

'我怎样才能','使用''Perl','来处理这个''行'
于 2010-04-01T15:19:04.153 回答