我想使用 GNUPlot 对极坐标图中的特定区域进行着色。该区域以 R (r1, r2) 和 Theta (t1, t2) 为界，因此最终形状是由极空间中的 4 个点定义的环形段。
在笛卡尔绘图中，很容易绘制一个矩形，或者是由(set object rect)4filledcurve个顶点组成的封闭形状。但是，由极坐标图中的 4 个点指定的填充曲线形状仍会产生四边形（具有恒定 R 的线应该是圆弧，而不是直线）。
有没有一种简单或直接的方法可以在极坐标中绘制这个形状？我尝试使用两条弧线，然后填充它们之间的空间，但到目前为止这还没有正常工作，我不确定是否有更好的方法来解决这个问题。
不幸的是，这并不容易。您可以设置circle您指定的开始和结束角度的对象。要切掉中心部分，您必须在上方绘制第二个白色圆圈：
set xrange [-1:1]
set yrange [-1:1]
set size ratio -1
r1 = 0.5
r2 = 1
theta1 = -30
theta2 = 60
set angles degrees
set style fill solid noborder
set object circle at first 0,0 front size r2 arc [theta1:theta2] fillcolor lt 1
set object circle at first 0,0 front size r1 fillcolor rgb 'white'
plot -10 notitle
这里很重要的是，x 和 y 轴具有相同的单位 ( set size ratio -1)，因为圆形对象是以第一个 x 轴为单位定义的，并且根本不考虑 y 轴。如果您没有其他要绘制的内容，则必须使用一个plot命令来绘制超出定义范围的内容。如果没有绘图，则不会绘制对象。
4.6.5 的结果是：
在即将发布的 5.0 版本中，您可以将伪数据（带有特殊文件名+）与filledcurves绘图样式一起使用：
r1 = 0.5
r2 = 1.0
theta1 = 20
theta2 = 135
set polar
set angles degrees
set size ratio -1
unset raxis
unset rtics
set trange [theta1:theta2]
set style fill solid noborder
plot '+' using 1:(r1):(r2) with filledcurves notitle
