7

我突然注意到TDataModuleTestExchange(nil)我们的代码库中有一个“构造函数调用”：

procedure TDialoogConfigExchange.ButtonTestClick(Sender: TObject);
var
   lDataModuleTestExchange: TDataModuleTestExchange;
   lResult                : Boolean;
begin
   inherited;
   [snip]
   begin
      lDataModuleTestExchange := TDataModuleTestExchange(nil);  // *** HERE ***
      try
         lResult := lDataModuleTestExchange.GetCalendarFolder(EditHost.Text,EditGebruiker.Text,EditWachtwoord.Text);
         if lResult then
            ToonMelding(sExchangeTestGelukt, mtInformation, [mbOk])
         else
            ToonMelding(Meldingen.Text, mtError, [mbOK]);
      finally
         lDataModuleTestExchange.Free;
      end;
   end;
end;

所以代替TDataModuleTestExchange.**Create**(nil)这个工作就好了！

unit dmTestExchange;

interface

uses
  System.SysUtils, System.Classes,
  Xml.XMLDoc, Xml.XMLIntf, Xml.XMLDOM,
  TimeTellDM;

type
  TDataModuleTestExchange = class(TTimeTellDataModule)  // TDataModule descendant
  private
  public
    function GetCalendarFolder(const AExchangeServerURL,AExchangeLoginName,AExchangePass: String): Boolean;
  end;

没有编译器错误，没有运行时问题。怎么来的？

4

1 回答 1

5

首先，值得指出的是，演员阵容是虚假的，除了混淆之外没有其他目的。代码等价于：

lDataModuleTestExchange := nil;

TDataModuleTestExchange.GetCalendarFolder是一个实例方法，您在引用上调用它nil。如果该方法尝试访问实例中的任何字段，或调用虚拟方法，或者实际上任何依赖于该实例的东西，这将导致运行时错误。因此，似乎 的实现TDataModuleTestExchange.GetCalendarFolder不依赖于实例。尽管您似乎在这里逃脱了这一点，但编写这样的代码显然是非常糟糕的形式。

该类可能应该被重写以声明一个静态类方法，如下所示：

type
  TDataModuleTestExchange = class(TTimeTellDataModule)  
  public
    class function GetCalendarFolder(const AExchangeServerURL,  
      AExchangeLoginName, AExchangePass: string): Boolean; static;
  end;

然后像这样调用：

lResult := TDataModuleTestExchange.GetCalendarFolder(EditHost.Text,
  EditGebruiker.Text, EditWachtwoord.Text);
if lResult then
  ToonMelding(sExchangeTestGelukt, mtInformation, [mbOk])
else
  ToonMelding(Meldingen.Text, mtError, [mbOK]);
于 2014-08-12T14:31:16.243 回答