string - 如何在 for 循环中对变量执行字符串操作？

Question

这听起来很愚蠢，但我无法让它工作。我想我只是不明白两者之间的区别%%v, %v% and %v

这是我正在尝试做的事情：

for %%v in (*.flv) do ffmpeg.exe -i "%%v" -y -f mjpeg -ss 0.001 -vframes 1 -an "%%v.jpg"

这成功地为每部电影生成了一个缩略图，但问题是：

movie.flv -> movie.flv.jpg

所以我想做的就是去掉最后 4 个字符%%v并将其用于第二个变量。

我一直在尝试这样的事情：

%%v:~0,-3%

但它不起作用，我能想到的任何迭代也不起作用。

有任何想法吗？

Answer 1

对于发现此线程以寻找如何对 for 循环变量实际执行字符串操作的人（使用延迟扩展）：

setlocal enabledelayedexpansion

...

::Replace "12345" with "abcde"
for %%i in (*.txt) do (
    set temp=%%i
    echo !temp:12345=abcde!
)

Answer 2

for %%v in (*.flv) do ffmpeg.exe -i "%%v" -y -f mjpeg -ss 0.001 -vframes 1 -an "%%~nv.jpg"

来自“帮助”：

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

Answer 3

使用 %%~nV 仅获取文件名。

Answer 4

我不擅长批处理（我使用 WSH 或其他脚本语言代替），但我可以尝试解释 %%v %v 和 %v%。

前两种形式for循环使用。help for解释了差异，第一种形式用于批处理文件，而第二种形式用于直接在命令提示符下键入（粘贴）命令时使用。

最后一种形式只是将变量名（环境变量）替换为其值：

set FOO=C:\bar\foo
cd %FOO%\gah

Answer 5

我更喜欢的另一种方法是创建一个子例程(:processMpeg)，我为 For 循环中的每个元素调用它，我将 %%v 变量传递给它。

for %%v in (*.flv) do call :processMpeg "%%v"
goto :eof

:processMpeg
  set fileName=%~n1
  echo P1=%1  fileName=%fileName%  fullpath=%~dpnx1
  ffmpeg.exe -i "%~1" -y -f mjpeg -ss 0.001 -vframes 1 -an "%filename%.jpg"
  goto :eof