88

我可以使用 Emacs 中的哪些命令将当前日期和时间插入文件的文本缓冲区？

（例如，记事本中的等效功能只是按 F5，这是记事本唯一有用的功能！）

4

11 回答 11

141 
C-u M-! date
于 2008-11-09T11:44:03.250 回答
44

放入您的 .emacs 文件：

;; ====================
;; insert date and time

(defvar current-date-time-format "%a %b %d %H:%M:%S %Z %Y"
  "Format of date to insert with `insert-current-date-time' func
See help of `format-time-string' for possible replacements")

(defvar current-time-format "%a %H:%M:%S"
  "Format of date to insert with `insert-current-time' func.
Note the weekly scope of the command's precision.")

(defun insert-current-date-time ()
  "insert the current date and time into current buffer.
Uses `current-date-time-format' for the formatting the date/time."
       (interactive)
       (insert "==========\n")
;       (insert (let () (comment-start)))
       (insert (format-time-string current-date-time-format (current-time)))
       (insert "\n")
       )

(defun insert-current-time ()
  "insert the current time (1-week scope) into the current buffer."
       (interactive)
       (insert (format-time-string current-time-format (current-time)))
       (insert "\n")
       )

(global-set-key "\C-c\C-d" 'insert-current-date-time)
(global-set-key "\C-c\C-t" 'insert-current-time)

参考

于 2008-10-30T22:01:24.710 回答
33

我使用了这些简短的片段：

(defun now ()
  "Insert string for the current time formatted like '2:34 PM'."
  (interactive)                 ; permit invocation in minibuffer
  (insert (format-time-string "%D %-I:%M %p")))

(defun today ()
  "Insert string for today's date nicely formatted in American style,
e.g. Sunday, September 17, 2000."
  (interactive)                 ; permit invocation in minibuffer
  (insert (format-time-string "%A, %B %e, %Y")))

他们最初来自journal.el

于 2009-03-06T16:41:40.330 回答
27

对于插入日期：

M-x org-time-stamp

对于插入日期时间：

C-u M-x org-time-stamp

您可以为此命令绑定全局键。

org-mode的方法非常人性化，您可以从日历中选择任何日期。

于 2013-06-13T03:23:21.603 回答
15

您可以安装yasnippet，它可以让您输入“时间”和 tab 键，并且还可以做更多的事情。current-time-string它只是在幕后调用，因此您可以使用format-time-string.

于 2008-10-30T23:07:25.373 回答
5

这是我不久前写的一个包，它可以满足您的要求。

http://github.com/rmm5t/insert-time.el/tree/master/insert-time.el

(require 'insert-time)
(define-key global-map [(control c)(d)] 'insert-date-time)
(define-key global-map [(control c)(control v)(d)] 'insert-personal-time-stamp)
于 2008-10-30T22:06:52.470 回答
2

M-1 M-！日期

这会导致您运行的 shell 命令被插入到您当前正在编辑的缓冲区中，而不是新的缓冲区中。

于 2010-03-02T08:59:04.833 回答
2

最简单的方法可能是：

（插入（当前时间字符串））

于 2020-04-24T22:48:26.093 回答
1

谢谢，CMS！我的变化，不管它的价值——让我很高兴：

(defvar bjk-timestamp-format "%Y-%m-%d %H:%M"
  "Format of date to insert with `bjk-timestamp' function
%Y-%m-%d %H:%M will produce something of the form YYYY-MM-DD HH:MM
Do C-h f on `format-time-string' for more info")


(defun bjk-timestamp ()
  "Insert a timestamp at the current point.
Note no attempt to go to beginning of line and no added carriage return.
Uses `bjk-timestamp-format' for formatting the date/time."
       (interactive)
       (insert (format-time-string bjk-timestamp-format (current-time)))
       )

我把它放在一个由我的 .emacs 调用的文件中，使用：

(load "c:/bjk/elisp/bjk-timestamp.el")

这两者都使修改变得更容易，而不会冒险破坏我的 .emacs 中的其他内容，并且让我可以轻松地进入也许有一天真正了解这个 Emacs Lisp 编程的全部内容。

PS 对我的 n00b 技术的评论非常受欢迎。

于 2010-08-18T05:54:06.430 回答
0

这是我的看法。

(defun modi/insert-time-stamp (option)
  "Insert date, time, user name - DWIM.

If the point is NOT in a comment/string, the time stamp is inserted prefixed
with `comment-start' characters.

If the point is IN a comment/string, the time stamp is inserted without the
`comment-start' characters. If the time stamp is not being inserted immediately
after the `comment-start' characters (followed by optional space),
the time stamp is inserted with “--” prefix.

If the buffer is in a major mode where `comment-start' var is nil, no prefix is
added regardless.

Additional control:

        C-u -> Only `comment-start'/`--' prefixes are NOT inserted
    C-u C-u -> Only user name is NOT inserted
C-u C-u C-u -> Both prefix and user name are not inserted."
  (interactive "P")
  (let ((current-date-time-format "%a %b %d %H:%M:%S %Z %Y"))
    ;; Insert a space if there is no space to the left of the current point
    ;; and it's not at the beginning of a line
    (when (and (not (looking-back "^ *"))
               (not (looking-back " ")))
      (insert " "))
    ;; Insert prefix only if `comment-start' is defined for the major mode
    (when (stringp comment-start)
      (if (or (nth 3 (syntax-ppss)) ; string
              (nth 4 (syntax-ppss))) ; comment
          ;; If the point is already in a comment/string
          (progn
            ;; If the point is not immediately after `comment-start' chars
            ;; (followed by optional space)
            (when (and (not (or (equal option '(4)) ; C-u or C-u C-u C-u
                                (equal option '(64))))
                       (not (looking-back (concat comment-start " *")))
                       (not (looking-back "^ *")))
              (insert "--")))
        ;; If the point is NOT in a comment
        (progn
          (when (not (or (equal option '(4)) ; C-u or C-u C-u C-u
                         (equal option '(64))))
            (insert comment-start)))))
    ;; Insert a space if there is no space to the left of the current point
    ;; and it's not at the beginning of a line
    (when (and (not (looking-back "^ *"))
               (not (looking-back " ")))
      (insert " "))
    (insert (format-time-string current-date-time-format (current-time)))
    (when (not (equal option '(16))) ; C-u C-u
      (insert (concat " - " (getenv "USER"))))
    ;; Insert a space after the time stamp if not at the end of the line
    (when (not (looking-at " *$"))
      (insert " "))))

我更喜欢将此绑定到C-c d.

于 2015-03-31T17:35:16.750 回答
0

要插入日期：

C-c . RET

选择日期左/右/上/下 - RET（回车）

于 2021-06-29T21:20:57.500 回答