5

是否可以使用 DOSKEY 调用别名？简单的例子..我想做这样的事情：

DOSKEY a=someCommand
DOSKEY b=someOtherCommand
DOSKEY c=andAThirdCommand

:: How to do this? -> DOSKEY all=a+b+c

我已经知道我可以通过写这个来做到这一点：

DOSKEY all=someCommand ^& someOtherCommand ^& andAThirdCommand

但在重用东西的意义上，我想从上面重用我定义的别名。有没有可能如我所愿？

谢谢！

PS：在这里看到了这个，但这不是一个令人满意的答案。似乎它不会起作用。:(

4

1 回答 1

3

好问题，很难回答……但是，我可以建议一个使用简单批处理脚本的解决方法。

假设我们已经定义了doskey a=commandAanddoskey a=commandB和doskey c=commandC宏。

  1. 静态方法：让我们命名我们的脚本，例如dem（define m acro ）并将它放在你的path. 然后dem acb a c b应该定义一个新的宏 acb（准备进一步使用）如下doskey acb=commandA $T commandC $T commandB：该脚本可以通过对dsk提供的脚本进行一些修改来建立（提示：不是启动宏文本，而是构成新宏的文本，但要注意另一个转义）。

  2. 动态方法：让我们将脚本命名为例如dsk( d o sk ey) 并将其放在您的path. 然后dsk a b c应该调用宏 a，b并按c该顺序。传递给脚本的参数（宏名称）的数量不受限制。该脚本适用于非常简单定义的宏，但是

    • 允许%在宏中使用百分号doskey a=echo %variable%和/或甚至for在循环中使用doskey a=for /F "tokens=*" %G in ('dir /b /s *.txt') do @echo %G；
    • 允许$T在宏中连接命令（相当于&在批处理文件中），例如doskey a=dir $T set；通过替换$T来完成&（在极少数情况下还不够，然后需要单独拆分和执行命令）。

已知问题和/或限制（在不了解所用宏的真实结构的情况下无法解决）；dsk脚本_

  • 循环for可能会带来%%parameter变量问题；否决在宏中使用：（%%{外循环）和%%? %%@（内循环）
  • 不考虑管道或重定向，例如doskey a=dir ^> somefile；
  • 不允许^&宏中的串联命令（但允许doskey内在$T串联）；
  • 不允许启动批处理.bat或.cmd脚本（需要call %xitem%而不是%xitem%在:doItem程序中（cca 第 50 行）；
  • 如果没有找到宏名称，它只是被跳过了......

脚本dsk如下：

:: dsk.bat
@ECHO OFF >NUL
@SETLOCAL enableextensions enabledelayedexpansion
set "CheckOnly=0"

set "DoneList="
set "ToDoList="
set "xitem=x"
for %%{ in (%*) do (
  set "_G_found=0"
  echo.
  for /F "tokens=1* delims==" %%? in ('doskey /macros') do (
    if /i "%%{"=="%%?" (
      for /F "tokens=*" %%_ in ("%%@") do set "item=%%_"
      if /i "!item:~0,3!"=="for" set "item=!item:%%=%%%%!"
      if "%CheckOnly%"=="1" (
          echo :  to do: '!item!'
      ) else (
          echo :  To Do: '!item!'
          call :doItem !item!
      )
      set "DoneList=!DoneList! +%%{"
      set "_G_found=1"
    ) 
  )
  if "!_G_found!"=="0" (
    set "DoneList=!DoneList! -%%{"
    echo :  macro: [%%{] ^(not found^)
    if "!ToDoList!"=="" set "ToDoList=!ToDoList!, [%%{]"
    if "!ToDoList!"=="!ToDoList:[%%{]=!" set "ToDoList=!ToDoList!, [%%{]"
  )
)
echo.
echo :  
echo :    trailing progress report
echo :  
if "%ToDoList%"=="" (
    echo :    all found: %DoneList:~1%
) else (
    echo :    +found, -not found: %DoneList:~1%
    echo :   %ToDoList:~2% not found in macro name list 
)
echo :    end of batch %~f0
echo :  
:endlocal
@ENDLOCAL
@goto :eof

:doItem
  set "xitem=%*"
  set "xitem=%xitem:$T=&%"
  %xitem%
@goto :eof

下一个场景：

d:\bat>doskey /macros
y=for /F "tokens=*" %g in ('dir /b rand.bat') do @echo %g
x=dir /B /AD $T dir /B /AD "D:\Remote\bat\COCL\bu bu bu" $T set y
a=echo CheckOnly=%CheckOnly%
b=rand.bat

并且dsk y b a x ncall 给出下一个输出：

d:\bat>dsk y b a x n

:  To Do: 'for /F "tokens=*" %%g in ('dir /b rand.bat') do @echo %%g'
rand.bat

:  To Do: 'rand.bat'
The system cannot find the batch label specified - doItem

:  To Do: 'echo CheckOnly=%CheckOnly%'
CheckOnly=0

:  To Do: 'dir /B /AD $T dir /B /AD "D:\Remote\bat\COCL\bu bu bu" $T set y'
files
a.dot 1.dot 2.dot 3
Environment variable y not defined

:  macro: [n] (not found)

:
:    trailing progress report
:
:    +found, -not found: +y +b +a +x -n
:   [n] not found in macro name list
:    end of batch d:\bat\dsk.bat
:
d:\bat>

出于调试目的，该脚本相当冗长（以及变量CheckOnly，值1= 仅回显命令， =在宏中0回显和执行命令）。

于 2015-01-03T05:21:54.553 回答