313

我有这个sql：

ALTER TABLE dbo.ChannelPlayerSkins
    DROP CONSTRAINT FK_ChannelPlayerSkins_Channels

但显然，在我们使用的其他一些数据库上，约束具有不同的名称。如何检查 name 是否存在约束FK_ChannelPlayerSkins_Channels。

4

14 回答 14

403

试试这个：

SELECT
    * 
    FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS 
    WHERE CONSTRAINT_NAME ='FK_ChannelPlayerSkins_Channels'

- 编辑 -

当我最初回答这个问题时，我在想“外键”，因为最初的问题是关于查找“FK_ChannelPlayerSkins_Channels”。从那时起，许多人评论说要找到其他“约束”，这里有一些其他查询：

--Returns one row for each CHECK, UNIQUE, PRIMARY KEY, and/or FOREIGN KEY
SELECT * 
    FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS
    WHERE CONSTRAINT_NAME='XYZ'  


--Returns one row for each FOREIGN KEY constrain
SELECT * 
    FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS 
    WHERE CONSTRAINT_NAME='XYZ'


--Returns one row for each CHECK constraint 
SELECT * 
    FROM INFORMATION_SCHEMA.CHECK_CONSTRAINTS
    WHERE CONSTRAINT_NAME='XYZ'

这是另一种方法

--Returns 1 row for each CHECK, UNIQUE, PRIMARY KEY, FOREIGN KEY, and/or DEFAULT
SELECT 
    OBJECT_NAME(OBJECT_ID) AS NameofConstraint
        ,SCHEMA_NAME(schema_id) AS SchemaName
        ,OBJECT_NAME(parent_object_id) AS TableName
        ,type_desc AS ConstraintType
    FROM sys.objects
    WHERE type_desc LIKE '%CONSTRAINT'
        AND OBJECT_NAME(OBJECT_ID)='XYZ'

如果您需要更多约束信息，请查看系统存储过程内部master.sys.sp_helpconstraint以了解如何获取某些信息。要使用 SQL Server Management Studio 查看源代码，请进入“对象资源管理器”。从那里展开“Master”数据库，然后展开“Programmability”，然后展开“Stored Procedures”，然后展开“System Stored Procedures”。然后您可以找到“sys.sp_helpconstraint”并右键单击它并选择“修改”。请注意不要保存对它的任何更改。此外，您可以在任何表上使用此系统存储过程，例如EXEC sp_helpconstraint YourTableNameHere.

于 2010-03-23T11:23:56.917 回答
290

检查约束是否存在的最简单方法（如果存在则执行诸如删除它之类的操作）是使用 OBJECT_ID() 函数...

IF OBJECT_ID('dbo.[CK_ConstraintName]', 'C') IS NOT NULL 
    ALTER TABLE dbo.[tablename] DROP CONSTRAINT CK_ConstraintName

OBJECT_ID 可以在没有第二个参数的情况下使用（'C' 仅用于检查约束），这也可能有效，但如果您的约束名称与数据库中其他对象的名称匹配，您可能会得到意想不到的结果。 

IF OBJECT_ID('dbo.[CK_ConstraintName]') IS NOT NULL 
    ALTER TABLE dbo.[tablename] DROP CONSTRAINT CK_ConstraintName

OBJECT_ID 也可以与其他“约束”一起使用，例如外键约束或主键约束等。为获得最佳结果，请始终包含适当的对象类型作为 OBJECT_ID 函数的第二个参数：

约束对象类型：

  • C = CHECK 约束
  • D = DEFAULT（约束或独立）
  • F = FOREIGN KEY 约束
  • PK = PRIMARY KEY 约束
  • R = 规则（旧式，独立）
  • UQ = UNIQUE 约束

另请注意，通常需要模式。约束的模式一般采用父表的模式。

使用此方法时未能将您的约束（或您正在检查的任何内容）放在括号中也可能导致误报——如果您的对象使用不寻常的字符（例如 .），则需要括号。

于 2013-03-25T22:08:50.323 回答
47

如果您正在寻找其他类型的约束，例如默认值，您应该使用不同的查询（来自How do I find a default constraint using INFORMATION_SCHEMA? devio回答）。采用：

SELECT * FROM sys.objects WHERE type = 'D' AND name = @name

按名称查找默认约束。

我在我的帖子“ DDL 'IF not Exists”条件中组合了不同的“IF not Exists”检查，以使 SQL 脚本可重新运行”

于 2011-07-27T04:49:01.620 回答
31 
IF (OBJECT_ID('FK_ChannelPlayerSkins_Channels') IS NOT NULL)
于 2012-05-31T14:24:42.190 回答
20

你在看这样的东西吗，下面是在 SQL Server 2005 中测试的

SELECT * FROM sys.check_constraints WHERE 
object_id = OBJECT_ID(N'[dbo].[CK_accounts]') AND 
parent_object_id = OBJECT_ID(N'[dbo]. [accounts]')
于 2010-03-23T11:18:52.220 回答
10

只是需要注意的事情......

在 SQL Server 2008 R2 SSMS 中，“Script Constraint as -> DROP And CREATE To”命令生成如下所示的 T-SQL

USE [MyDatabase]
GO

IF  EXISTS (SELECT * FROM dbo.sysobjects WHERE id = OBJECT_ID(N'[DEF_Detail_IsDeleted]') AND type = 'D')
BEGIN
ALTER TABLE [Patient].[Detail] DROP CONSTRAINT [DEF_Detail_IsDeleted]
END

GO

USE [MyDatabase]
GO

ALTER TABLE [Patient].[Detail] ADD  CONSTRAINT [DEF_Detail_IsDeleted]  DEFAULT ((0)) FOR [IsDeleted]
GO

开箱即用，此脚本不会删除约束，因为 SELECT 返回 0 行。（请参阅帖子Microsoft Connect）。

默认约束的名称是错误的，但我认为它也与 OBJECT_ID 函数有关，因为更改名称并不能解决问题。

为了解决这个问题，我删除了 OBJECT_ID 的使用，而是使用了默认的约束名称。

(SELECT * FROM dbo.sysobjects WHERE [name] = (N'DEF_Detail_IsDeleted') AND type = 'D')
于 2012-06-21T22:04:03.507 回答
8

在创建约束之前，我使用以下查询来检查现有约束。

IF (NOT EXISTS(SELECT 1 FROM sysconstraints WHERE OBJECT_NAME(constid) = 'UX_CONSTRAINT_NAME' AND OBJECT_NAME(id) = 'TABLE_NAME')) BEGIN
...
END

这会按名称查询以给定表名为目标的约束。希望这可以帮助。

于 2014-06-17T08:46:28.773 回答
3 
IF EXISTS(SELECT 1 FROM sys.foreign_keys WHERE parent_object_id = OBJECT_ID(N'dbo.TableName'))
 BEGIN 
ALTER TABLE TableName DROP CONSTRAINT CONSTRAINTNAME 
END
于 2014-09-19T07:16:08.167 回答
3 
IF EXISTS(SELECT TOP 1 1 FROM sys.default_constraints WHERE parent_object_id = OBJECT_ID(N'[dbo].[ChannelPlayerSkins]') AND name = 'FK_ChannelPlayerSkins_Channels')
BEGIN
    DROP CONSTRAINT FK_ChannelPlayerSkins_Channels
END
GO
于 2017-08-22T17:43:24.070 回答
2

INFORMATION_SCHEMA是你的朋友。它具有显示各种模式信息的各种视图。检查您的系统视图。你会发现你有三个处理约束的视图，一个是CHECK_CONSTRAINTS.

于 2010-03-23T11:14:31.997 回答
1

我用它来检查列上的远程约束。它应该有你需要的一切。

DECLARE
  @ps_TableName VARCHAR(300)
  , @ps_ColumnName VARCHAR(300)

SET @ps_TableName = 'mytable'
SET @ps_ColumnName = 'mycolumn'

DECLARE c_ConsList CURSOR LOCAL STATIC FORWARD_ONLY FOR
    SELECT
    'ALTER TABLE ' + RTRIM(tb.name) + ' drop constraint ' + sco.name AS csql
    FROM
        sys.Objects tb
        INNER JOIN sys.Columns tc on (tb.Object_id = tc.object_id)
        INNER JOIN sys.sysconstraints sc ON (tc.Object_ID = sc.id and tc.column_id = sc.colid)
        INNER JOIN sys.objects sco ON (sc.Constid = sco.object_id)
    where
        tb.name=@ps_TableName
        AND tc.name=@ps_ColumnName
OPEN c_ConsList
FETCH c_ConsList INTO @ls_SQL
WHILE (@@FETCH_STATUS = 0) BEGIN

    IF RTRIM(ISNULL(@ls_SQL, '')) <> '' BEGIN
        EXECUTE(@ls_SQL)
    END
    FETCH c_ConsList INTO @ls_SQL
END
CLOSE c_ConsList
DEALLOCATE c_ConsList
于 2013-03-21T20:13:10.153 回答
1

您可以使用上面的一个警告：

IF EXISTS(
    SELECT 1 FROM sys.foreign_keys 
    WHERE parent_object_id = OBJECT_ID(N'dbo.TableName') 
        AND name = 'CONSTRAINTNAME'
)
BEGIN 
    ALTER TABLE TableName DROP CONSTRAINT CONSTRAINTNAME 
END

需要使用，name = [Constraint name]因为一个表可能有多个外键，但仍然没有检查外键

于 2017-04-17T18:08:18.093 回答
0 
SELECT tabla.name as Tabla,

        restriccion.name as Restriccion, 
        restriccion.type as Tipo, 
        restriccion.type_desc as Tipo_Desc
FROM {DATABASE_NAME}.sys.objects tabla 

INNER JOIN {DATABASE_NAME}.sys.objects restriccion

ON tabla.object_id = restriccion.parent_object_id

WHERE tabla.type = 'U' - Solo tablas creadas por el usuario.

AND restriccion.type = 'UQ' --Tipo de Restriccion UNIQUE

ORDER BY tabla.name, restriccion.type_desc
于 2014-10-28T17:46:18.373 回答
0

在 mySql 中，您需要确保您正在查询正确的数据库！因此table_schema=DATABASE()

这是我使用 knex 来检查特定数据库和表中是否定义了特定外键或索引的函数

const isFKExists = async (knex, tableName, fkName) => {
  const result = await knex.raw(
    `SELECT COUNT(*) AS 'isExists' FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE table_schema=DATABASE() AND table_name='${tableName}' AND CONSTRAINT_NAME='${fkName}' AND CONSTRAINT_TYPE = 'FOREIGN KEY'`
  )
  return (result[0][0].isExists === 1)
}

const isIndexExists = async (knex, tableName, indexName) => {
  const result = await knex.raw(
    `SELECT COUNT(*) AS 'isExists' FROM INFORMATION_SCHEMA.STATISTICS WHERE table_schema=DATABASE() AND table_name='${tableName}' AND index_name='${indexName}'`
  )
  return (result[0][0].isExists > 0)
}

享受

于 2022-01-25T07:43:46.123 回答