1

我正在编写测试添加帐户功能的测试用例。这意味着我需要为帐户生成数据：姓名、电子邮件、参考号和订单号。我在想，对于这些字段中的每一个，我可以只生成一个带有前缀的随机单词或数字，以便我可以使用脚本定期从数据库中删除这些条目。

问题是，我不确定如何添加前缀或者实际上只是使用大多数faker 的关键字。

在我使用 md5 关键字创建一个可以用于我的测试用例的每个实例的字符串的那一刻，我通过在我的资源文件中创建一个变量来做到这一点：

*** Variables ***
${md5}                MD 5

然后，每当我想写我的前缀时，我都会调用这个变量（我在各个字段的末尾调用它，例如电子邮件：email+${md5}@gmail.com，参考：test ${md5} 等

*** Keywords ***
Write username
    Input Text    a11y-username    test ${md5}

我不确定在 Robot Framework 中使用 faker 的实际文档在哪里，我正在使用http://fake-factory.readthedocs.org/en来查找我想要使用的提供程序，然后努力让它们工作从射频内部。

任何人都可以帮助我使 random_int() 正常工作，或者将我指向RF 中所有伪造者提供者的相关文档。

提前致谢。

4

1 回答 1

2

概述

使用 faker 关键字只需要调用它们，并将结果保存在变量中。您不能在变量表中使用 faker 关键字，您需要在测试用例或关键字中使用它们。但是，您可以使用 python 变量文件直接调用 faker 命令。

例如，要获取地址，您可以调用Address关键字。因为伪造的关键字非常通用，所以我建议对关键字进行完全限定，以明确您正在生成虚假数据。

例如：

*** Settings ***
| Library | FakerLibrary | WITH NAME | faker

*** Test Cases ***
| Example of using faker
| | ${address}= | faker.Address
| | log | address: ${address}

使用 Random Int 关键字

要获取随机整数，请使用 Random Integer 关键字：

| Example of using faker to get a random integer
| | ${number}= | faker.Random Int
| | log | my number is ${number}

为整个套件初始化变量

如果您想对整个套件使用相同的值，您可以编写一个关键字，使用Set Suite Variable关键字设置一些套件级变量。

例如：

*** Settings ***
| Library | FakerLibrary | WITH NAME | faker
| Suite Setup | Initialize Test Data

*** Test Cases ***
| Example of using faker to initialize suite variables
| | log | The suite address is ${address}
| | log | The suite md5 is ${md5}
| | log | The suite number is ${number}


*** Keywords ***
| Initialize test data
| | ${address}= | faker.Address
| | ${md5}= | faker.MD5
| | ${number}= | faker.Random Int
| | 
| | Set suite variable | ${address}
| | Set suite variable | ${md5}
| | Set suite variable | ${number}

文档

FakerLibrary 关键字文档可在https://guykisel.github.io/robotframework-faker/获得。

于 2014-07-21T16:11:38.677 回答