5

我正在将 History.js 中的绑定编写到 PureScript 中，但仍在努力理解 Eff monad、一排效果是什么以及它们为何有价值。现在我写了以下内容EasyFFI

type Title        = String
type Url          = String
type State        = forall a. {title :: Title, url :: Url | a}
type Data         = forall a. { | a}
type StateUpdater = Data -> Title -> Url -> Unit

-- this function is a work around for 'data' as a reserved word.
foreign import getData 
  "function getData(state){ return state['data']; }" 
  :: forall a b. { | a} -> b

unwrapState :: StateUpdater -> State -> Unit
unwrapState f s = f (getData s) s.title s.url

replaceState' :: StateUpdater
replaceState' = unsafeForeignProcedure ["data","title","url"] "History.replaceState(data,title,url)"
replaceState :: State -> Unit
replaceState = unwrapState replaceState'

foreign import data BeforeEach :: !
beforeEach :: forall e a. Eff e a ->  Eff (beforeEach :: BeforeEach | e) Unit
beforeEach = unsafeForeignProcedure ["fn",""] "window.beforeEach(fn);"

稍后在代码中我有以下内容：

beforeEach $ do 
  replaceState {title = "wowzers!", url = "/foos"}

并得到以下错误

 Cannot unify Prelude.Unit with Control.Monad.Eff.Eff u2518 u2517.

我尝试以各种方式操纵类型签名以尝试使其全部对齐，但我真的不明白出了什么问题。所以它只是在这一点上猜测。

4

1 回答 1

5

我对您的代码的修改版本在这篇文章的末尾，但我必须进行一些修改才能使其编译：

我假设您的意图是让您StateUpdater对浏览器历史记录产生影响，所以我更改了它的类型以使用Eff具有新History效果类型的 monad。这是主要问题，因为您使用的最后一行replaceState的结果类型不在Effmonad 中。这导致了您看到的类型错误。

我将类型同义词中的一些普遍量化的类型变量移到了函数类型中。我还删除了您的Data类型同义词并将数据内容移动到类型中的新data字段中State。

这很重要，因为您之前的Data类型没有居民。有一个常见的误解（出于我不明白的原因），这forall a. { | a}是一种“我不关心字段”的记录。这是不正确的——这种类型表示包含所有可能存在的字段的记录类型，并且这种类型显然是无人居住的。从调用者的角度来看，forall a. {| a} -> r两者之间存在重要差异。(forall a. {| a}) -> r

回答您最初的问题：“什么是一排效果，它们为什么有用？” - 行最初被添加到 PureScript 以处理记录类型的多态性，而不必求助于子类型。行允许我们为使用记录的函数赋予多态类型，这样我们就可以将“记录的其余部分”捕获为类型系统中的一个概念。

在处理效果时，行也被证明是一个有用的概念。就像我们不关心记录的其余部分是什么一样，我们通常也不关心一组效果的其余部分是什么样的，只要所有效果都在类型系统中正确传播即可。

举个例子，我修改的代码中涉及到两个效果：History和你的BeforeEach. 动作beforeEach和replaceState每个动作只使用这些效果之一，但它们的返回类型是多态的。这允许两个函数的组合main具有两种效果，并且可以正确键入。main具有类型forall eff. Eff (history :: History, beforeEach :: BeforeEach | eff) {}，这是最通用的类​​型，由类型检查器推断。

简而言之，效果系统中的行提供了一种巧妙的方式来处理各种“本机”效果的交错，因此开发人员不必担心效果顺序或lifting 计算之类的事情mtl。

module Main where

import EasyFFI
import Control.Monad.Eff

type Title        = String
type Url          = String
type State d      = { title :: Title, url :: Url, "data" :: { | d } }

type StateUpdater d = forall eff. { | d } -> Title -> Url -> Eff (history :: History | eff) {}

foreign import data History :: !

unwrapState :: forall eff d. StateUpdater d -> State d -> Eff (history :: History | eff) {}
unwrapState f s = f s."data" s.title s.url

replaceState' :: forall d. StateUpdater d
replaceState' = unsafeForeignProcedure ["d","title","url"] "History.replaceState(d,title,url)"

replaceState :: forall eff d. State d -> Eff (history :: History | eff) {}
replaceState = unwrapState replaceState'

foreign import data BeforeEach :: !

beforeEach :: forall e a. Eff e a ->  Eff (beforeEach :: BeforeEach | e) {}
beforeEach = unsafeForeignProcedure ["fn",""] "window.beforeEach(fn);"

main = beforeEach $ do 
  replaceState { title: "wowzers!", url: "/foos", "data": {} }
于 2014-07-16T16:12:06.167 回答