0

我需要使用 XSL 复制我的 xml 记录两次，没有任何 1 可以指导我。xml看起来像

<data> <record> <a>ABC</a> <b>ABC</b> <c>ARUN</c> <d>JAY</d> <e>SHREE</e> <f>MAKU</f> <z>MACK</z> </record> </data>

条件是 IF(a=b) 那么我们必须创建两条记录，即 a,b,c,d,e,z ​​和第二条记录，即 a,b,c,d,f,z 。和 IF(a!=b) 比只有 1 条记录，即 a、b、c、d、f、z。我已经完成了后半部分，但不能写两次记录。

我的 XSL 看起来像：-

`<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<xsl:for-each select="data/record">
<xsl:value-of select='a'/>
<xsl:value-of select='b'/>
<xsl:value-of select='c'/>
<xsl:value-of select='d'/>
<xsl:variable name="A" select='a'/>
<xsl:variable name="B" select='b'/>
<xsl:choose>
<xsl:when test="$A = $B">
<xsl:call-template name="test" />
</xsl:when> 
<xsl:otherwise>
<xsl:value-of select='f'/>
</xsl:otherwise>
</xsl:choose>
<xsl:value-of select='z'/>
</xsl:for-each> 
</xsl:template> 
<xsl:template name="test">
<xsl:value-of select='e'/>
<br/>
<xsl:value-of select='f'/>
</xsl:template>
</xsl:stylesheet>`

any1 可以帮我写两次记录吗？

4

2 回答 2

0

我的预期输出如下：-1st Record ABC,ABC,ARUN,JAY,SHREE,MACK。2nd Record ABC,ABC,ARUN,JAY,MAKU,MACK。

这并没有回答我的问题，记录之间有什么区别。假设您的输出是文本，并且每条记录都在自己的行上，您可以这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:template match="/">
    <xsl:for-each select="data/record">
        <xsl:if test="a = b">
            <xsl:value-of select="concat(a, b, c, d, e, z)"/>
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
        <xsl:value-of select="concat(a, b, c, d, f, z)"/>
        <xsl:if test="position != last()">
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

导致：

ABCABCARUNJAYSHREEMACK
ABCABCARUNJAYMAKUMACK

在你的例子中。

编辑：

尽管连接很简单，但您可能希望通过预先计算两个记录的公共部分来最大程度地减少工作量：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:variable name="sep">, </xsl:variable>

<xsl:template match="/">
    <xsl:for-each select="data/record">
        <xsl:variable name="common-start">
             <xsl:value-of select="concat(a, $sep, b, $sep, c, $sep, d, $sep)"/>
        </xsl:variable>
        <xsl:variable name="common-end">
             <xsl:value-of select="concat($sep, z, '&#10;')"/>
        </xsl:variable>
        <xsl:if test="a = b">
            <xsl:value-of select="concat($common-start, e, $common-end)"/>
        </xsl:if>
            <xsl:value-of select="concat($common-start, f, $common-end)"/>
        <xsl:if test="position != last()">
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>
于 2014-07-15T12:28:57.543 回答
0

如果您确实想使用“调用模板”，那么这里有一些您可以使用的 XSLT。它使用命名模板，您可以在其中传递希望出现在每条记录中的节点。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="data">
   <xsl:for-each select="record">
       <xsl:if test="a=b">
           <xsl:call-template name="record">
               <xsl:with-param name="fields" select="a|b|c|d|e|z" />
           </xsl:call-template>
       </xsl:if>
       <xsl:call-template name="record">
           <xsl:with-param name="fields" select="a|b|c|d|f|z" />
       </xsl:call-template>
   </xsl:for-each> 
</xsl:template> 

<xsl:template name="record">
   <xsl:param name="fields" />
   <xsl:for-each select="$fields">
       <xsl:if test="position() != 1">,</xsl:if>
       <xsl:value-of select="." />
   </xsl:for-each>
   <xsl:value-of select="'&#10;'" />
</xsl:template>
</xsl:stylesheet>

请注意，这只会按文档顺序输出元素，而不管您在xsl:with-param中“选择”它们的顺序如何。也就是说，这样做...

 <xsl:with-param name="fields" select="a|b|c|d|e|z" />

...将产生与此完全相同的输出....

<xsl:with-param name="fields" select="z|e|d|c|b|a" />

或者，您可以像这样编写语句

<xsl:with-param name="fields" select="*[not(self::f)]" />
于 2014-07-16T07:47:50.490 回答