2

我有一组节点

<menuList>
  <mode name="aasdf"/>
  <mode name="vfssdd"/>
  <mode name="aswer"/>
  <mode name="ddffe"/>
  <mode name="ffrthjhj"/>
  <mode name="dfdf"/>
  <mode name="vbdg"/>
  <mode name="wewer"/>
  <mode name="mkiiu"/>
  <mode name="yhtyh"/>
  and so on...
</menuList>

我现在已经这样排序了

 <xsl:variable name="rtf">
    <xsl:for-each select="//menuList/mode">
       <xsl:sort data-type="text" order="ascending" select="@name"/>
          <xsl:value-of select="@name"/>
    </xsl:for-each>
 </xsl:variable>

现在我需要将排序数组中的任意元素获取到它的位置数。我正在使用代码：

<xsl:value-of select="exsl:node-set($rtf)[position() = 3]"/>

我得到一个响应错误。我应该怎么做？

4

2 回答 2

4

提供的代码中至少有两个错误：

  1. <xsl:value-of select="@name"/>

当存在多个相邻文本节点时，将它们合并为一个。结果是 RTF 只有一个（长）单个文本节点，并且没有第三个节点。

2.<xsl:value-of select="exsl:node-set($rtf)[position() = 3]"/>

这要求包含在 中的第三个节点exsl:node-set($rtf)，但exsl:node-set($rtf)它是扩展函数生成的临时树的文档节点exsl:node-set()——这只是一个节点。因此，上面的 XPath 表达式根本不选择任何东西。

一个正确的解决方案如下：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:msxsl="urn:schemas-microsoft-com:xslt"
 >

 <xsl:template match="/">
    <xsl:variable name="rtf">
        <xsl:for-each select="//menuList/mode">
           <xsl:sort data-type="text" order="ascending" select="@name"/>
              <xsl:copy-of select="."/>
        </xsl:for-each>
     </xsl:variable>
    <xsl:value-of select="msxsl:node-set($rtf)/*[position()=3]/@name"/>
 </xsl:template>
</xsl:stylesheet>
于 2010-03-18T16:47:55.873 回答
2

您<xsl:value-of>在变量中使用。这不会复制节点，而是复制它的字符串值（节点的@name属性值）。这意味着您生成一个包含连接字符串的变量，但没有任何结构。

尝试：

<xsl:variable name="rtf">
  <xsl:for-each select="//menuList/mode">
    <xsl:sort select="@name" data-type="text" order="ascending" />
    <xsl:copy-of select="."/>
  </xsl:for-each>
</xsl:variable>

现在您的变量包含一个结果树片段，该片段由<mode>您首选顺序的节点组成，这意味着：

<xsl:value-of select="exsl:node-set($rtf)/*[3]/@name" />
<!-- don't forget you have element nodes now! ^^^^^^ -->

会工作。还要注意…/*[position() = 3]和…/*[3]是一回事。

于 2010-03-18T16:44:34.467 回答