3

比方说，我有以下类型：

type LinkID = Int

data Link = Link {
  lid :: LinkID,
  llength :: Int
  }

data Snap = Snap {
  slid :: LinkID,
  slength :: Int
  }

现在，我想编写一个基于管道的函数来执行此操作：

getSnaps :: LinkID -> [Link] -> [Snap] -> [(LinkID, [Snap])]
getSnaps l lks snp = map (\x -> (lid x, filter (\y -> lid x == slid y) snp)) a
  where a = filter (\x -> lid x > l) lks

假设我已经有 和 的 Producers Link，Snap如何getSnaps从这两个 Producer 中实现 Pipes 世界中的上述功能：

psnap :: Producer Snap IO ()
psnap = undefined

plink :: Producer Link IO ()
plink = undefined

psnap和的实际类型plink更多（使用 attoparsec-pipes 创建），但我想知道如何实现 getSnaps frompsnap和的功能plink。有没有解决此类问题的正确方法？

4

1 回答 1

2

我提出的解决方案与您的代码非常相似。我刚刚将map其中Pipes.Prelude.map一个过滤器替换为Pipes.Prelude.filter：

import Pipes
import qualified Pipes.Prelude as Pipes

type LinkID = Int

data Link = Link
    { lid :: LinkID
    , llength :: Int
    }

data Snap = Snap
    { slid :: LinkID
    , slength :: Int
    }

getSnaps
    :: Monad m
    => LinkID
    -> Producer  Link            m ()
    -> Producer  Snap            m ()
    -> Producer (LinkID, [Snap]) m ()
getSnaps l lks snp = do
    snp' <- lift (Pipes.toListM snp)  -- Cache `snp` into the list `snp'`
    lks >-> Pipes.filter (\x -> lid x > l)
        >-> Pipes.map (\x -> (lid x, filter (\y -> lid x == slid y) snp'))

请注意，有一个重要的部分，即上述解决方案将snp Producer' 的内容严格加载到 list 中snp'。这样做的原因是我们要重复使用列表的内容，所以我们需要将整个列表缓存在内存中以供重复使用。

于 2014-07-10T01:59:53.753 回答