我有一个项目清单：
<item>a</item>
<item>x</item>
<item>c</item>
<item>z</item>
我想作为输出
z
c
x
a
我在文件中没有订单信息，我只想颠倒这些行。源文件的最后一行应该是输出的第一行。如何在不按项目内容排序的情况下使用 XSLT 解决这个问题，这会产生错误的结果？
问问题
3491 次
4 回答
3
我将介绍两个 XSLT 解决方案：
I. 带递归的 XSLT 1.0 请注意，此解决方案适用于任何节点集，不仅适用于节点是兄弟节点的情况：
这种转变：
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="/*">
<xsl:call-template name="reverse">
<xsl:with-param name="pList" select="*"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="reverse">
<xsl:param name="pList"/>
<xsl:if test="$pList">
<xsl:value-of
select="concat($pList[last()], '
')"/>
<xsl:call-template name="reverse">
<xsl:with-param name="pList"
select="$pList[not(position() = last())]"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
应用于此 XML 文档时：
<t>
<item>a</item>
<item>x</item>
<item>c</item>
<item>z</item>
</t>
产生想要的结果：
z
c
x
a
二、XSLT 2.0 解决方案：
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output method="text"/>
<xsl:template match="/*">
<xsl:value-of select="reverse(*)/string(.)"
separator="
"/>
</xsl:template>
</xsl:stylesheet>
当此转换应用于同一个 XML 文档时，会产生相同的正确结果。
于 2010-03-16T00:59:58.937 回答
2
XML 代码：
<?xml version="1.0" encoding="ISO-8859-1"?>
<!-- Edited by XMLSpy® -->
<device>
<element>a</element>
<element>x</element>
<element>c</element>
<element>z</element>
</device>
XSLT 代码：
<?xml version="1.0" encoding="ISO-8859-1"?>
<!-- Edited by XMLSpy® -->
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="//device">
<xsl:for-each select="element">
<xsl:sort select="position()" data-type="number" order="descending"/>
<xsl:text> </xsl:text>
<xsl:value-of select="."/>
<xsl:text> </xsl:text>
</xsl:for-each>
</xsl:template>
注意：如果您使用 data-type="number"，并且任何值都不是数字，则这些非数字值将排在数字值之前。这意味着如果您使用 order="ascending"，则非数字值首先出现；如果您使用 order="descending"，则非数字值显示在最后。
请注意，非数字值未排序；它们只是按照遇到的顺序出现在输出文档中。
此外，您可能会发现阅读此内容很有用：
于 2010-03-16T00:55:34.417 回答
1
不确定完整的 XML 是什么样子，所以我将其包裹在一个<doc>元素中以使其格式良好：
<doc>
<item>a</item>
<item>x</item>
<item>c</item>
<item>z</item>
</doc>
针对此样式表运行该示例 XML：
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" encoding="UTF-8" omit-xml-declaration="yes"/>
<xsl:template match="/">
<xsl:call-template name="reverse">
<xsl:with-param name="item" select="doc/item[position()=last()]" />
</xsl:call-template>
</xsl:template>
<xsl:template name="reverse">
<xsl:param name="item" />
<xsl:value-of select="$item" />
<!--Adds a line feed-->
<xsl:text> </xsl:text>
<!--Move on to the next item, if we aren't at the first-->
<xsl:if test="$item/preceding-sibling::item">
<xsl:call-template name="reverse">
<xsl:with-param name="item" select="$item/preceding-sibling::item[1]" />
</xsl:call-template>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
产生请求的输出：
z
c
x
a
您可能需要调整 xpath 以匹配您的实际 XML。
于 2010-03-16T00:43:14.707 回答
-1
考虑这个 XML 输入：
<?xml version="1.0" encoding="utf-8" ?>
<items>
<item>a</item>
<item>x</item>
<item>c</item>
<item>z</item>
</items>
XSLT：
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" />
<xsl:template match="/items[1]">
<xsl:variable name="items-list" select="." />
<xsl:variable name="items-count" select="count($items-list/*)" />
<xsl:for-each select="item">
<xsl:variable name="index" select="$items-count+1 - position()"/>
<xsl:value-of select="$items-list/item[$index]"/>
<xsl:value-of select="'
'"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
结果：
z
c
x
a
于 2010-03-16T12:18:29.553 回答