delphi - 将剪贴板中的文本保存到文件

Question

我正在尝试以下代码，该代码应将剪贴板文本保存到 Delphi XE6 中的文本文件中。代码运行良好，但在输出文件中仅生成垃圾值，即使剪贴板包含复制的文本片段也是如此。如何更改代码才能正常工作？

function SaveClipboardTextDataToFile(
  sFileTo : string ) : boolean;
var
  ps1,
  ps2   : PChar;
  dwLen : DWord;
  tf    : TextFile;
  hData : THandle;
begin
  Result := False;
  with Clipboard do
  begin
    try
      Open;
      if( HasFormat( CF_TEXT ) ) then
      begin
        hData :=
          GetClipboardData( CF_TEXT );

        ps1 := GlobalLock( hData );
        dwLen := GlobalSize( hData );

        ps2 := StrAlloc( 1 + dwLen );

        StrLCopy( ps2, ps1, dwLen );

        GlobalUnlock( hData );

        AssignFile( tf, sFileTo );
        ReWrite( tf );
        Write( tf, ps2 );
        CloseFile( tf );

        StrDispose( ps2 );

        Result := True;
      end;
    finally
      Close;
    end;
  end;
end;

Answer 1

你看到垃圾是因为CF_TEXT是 ANSI。您请求 ANSI 文本，操作系统将剪贴板内容转换为 ANSI，然后将其放入 unicode 字符串中。用于CF_UNICODETEXTunicode 应用程序。

还要考虑对问题的评论中提出的观点。

Answer 2

如果你有 Delphi XE6 那么你可以使用一些已经实现的功能

uses
  System.SysUtils,
  System.IOUtils,
  Vcl.Clipbrd;

function SaveClipboardTextDataToFile( const sFileTo : string ) : boolean;
var
  LClipboard : TClipboard;
  LContent : string;
begin
  // get the clipboard content as text
  LClipboard := TClipboard.Create;
  try
    LContent := LClipboard.AsText;
  finally
    LClipboard.Free;
  end;
  // save the text - if any - into a file
  if not LContent.IsEmpty
  then
    begin
      TFile.WriteAllText( sFileTo, LContent );
      Exit( True );
    end;

  Result := False;
end;