delphi - 如何通过拖动面板或框架或其中的任何组件来移动面板或框架？

Question

在白色全屏形式中，我将有来自同一来源的七帧。我想用鼠标移动它们并在退出时保存该位置，以便稍后在同一位置加载。如果我在delphi.about.com中获得的代码中按住鼠标并移动它，我可以移动它

但是，如果我单击该面板内的 WinControl，我当然不会从面板中获得 OnMouseDown。

我如何移动面板（或框架）来移动其中的任何控件，而无需对其拥有的每个组件进行编码？

Answer 1

这是一个简单的示例，它解释了我所指的叠加层：

TTransparentPanel = class(TPanel)
protected
  procedure WMEraseBkGnd(var msg: TWMEraseBkGnd); message WM_ERASEBKGND;
  procedure CreateParams(var params: TCreateParams); override;
end;

procedure TTransparentPanel.CreateParams(var params: TCreateParams);
begin
  inherited CreateParams(params);
  params.ExStyle := params.ExStyle or WS_EX_TRANSPARENT;
end;

procedure TTransparentPanel.WMEraseBkGnd(var msg: TWMEraseBkGnd);
begin
  SetBkMode (msg.DC, TRANSPARENT);
  msg.result := 1;
end;

在表格中你有这样的东西：

procedure TFormTest.FormCreate(Sender: TObject);
begin
  FTransparentPanel := TTransparentPanel.Create(Self);
  FTransparentPanel.Parent := self;
  FTransparentPanel.Align := alClient;
  FTransparentPanel.Visible := True;
  FTransparentPanel.OnMouseDown := FormMouseDown;
  FTransparentPanel.OnMouseUp := FormMouseUp;
  FTransparentPanel.OnMouseMove := FormMouseMove;
end;

procedure TFormTest.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift:
    TShiftState; X, Y: Integer);
var
  I: Integer;
begin
  // Check if there is a control under X, Y
  FMoveControl := nil;
  for I := 0 to ControlCount - 1 do
  begin
    if Controls[I] <> FTransparentPanel then
    begin
      if (Controls[I].Left <= X) and (Controls[I].Top <= Y) and
         ((Controls[I].Left + Controls[I].Width) >= X) and ((Controls[I].Top + Controls[I].Height) >= Y) then
      begin
        FMoveControl := Controls[I];
        break;
      end;
    end;
  end;
  if Assigned(FMoveControl) then
  begin
    FStartLeft := FMoveControl.Left;
    FStartTop := FMoveControl.Top;
    FStartX := X;
    FStartY := Y;
  end;
end;

procedure TFormTest.FormMouseMove(Sender: TObject; Shift: TShiftState; X, Y:
    Integer);
begin
  // Move it
  if Assigned(FMoveControl) then
  begin
    FMoveControl.Left := FStartLeft + (X - FStartX);
    FMoveControl.Top := FStartTop + (Y - FStartY);
  end;
end;

procedure TFormTest.FormMouseUp(Sender: TObject; Button: TMouseButton; Shift:
    TShiftState; X, Y: Integer);
begin
  FMoveControl := nil;
end;

当您移动控件时，它会闪烁一点，但应该让您知道如何继续。