0

这个想法是通过用户输入构造一个 URL，然后将此输出到 pastebin。

所以脚本运行，要求用户输入，然后完成 URL，然后进入 pastebin。至少，是这样的想法。

这是我到目前为止提出的代码：

Set WshShell = WScript.CreateObject("WScript.Shell")

dim strLink, defInc, remedy
defInc = "INC"
strLink=InputBox("Enter Incident ID",,defInc)

remedy = "https://1st_part_web_url"& strLink &"%22"

WshShell.Run "cmd.exe /c echo " & remedy & " | clip", 0, TRUE

这样我就没有任何输出到 pastebin。为什么不？

4

2 回答 2

0

在运行命令之前尝试回显命令，并尝试以可见的方式运行命令：

cmd = "cmd.exe /k echo " & remedy & " | clip"
WScript.Echo cmd
WshShell.Run cmd, 1, TRUE

命令看起来正确吗？您是否在命令提示符窗口中看到错误？

您也可以尝试一种不需要脱壳的替代方法：

Set ie = CreateObject("InternetExplorer.Application")
ie.Navigate("about:blank")
ie.document.parentwindow.clipboardData.SetData "text", remedy
ie.Quit
于 2014-06-18T08:50:12.287 回答
0 
Option Explicit

Dim URL

    URL = "https://somewhere/somePage?var1=something&var2=somethingMore&id=123456789"

    With WScript.CreateObject("WScript.Shell") 
        .Environment("Process").Item("URL")=URL
        .Run "cmd /c ""(cmd /v:on /c echo(!URL!)|clip"" ", 0, true
    End With

为避免转义 url 中可能存在的问题字符，此代码使用环境变量将信息传递给 cmd，cmd 会将信息通过管道传输到 clip.exe

于 2014-06-18T09:59:23.623 回答