2

我是 XSLT 的新手，无法解决以下问题：

我有一个这样的xml文件：

<root>
    <subset>
        <e id="A"></e>
        <e id="C"></e>
    </subset>

    <data>
        <info id="A" order="3" name="ANode"></info>
        <info id="B" order="4" name="BNode"></info>
        <info id="C" order="1" name="CNode"></info>
        <info id="D" order="2" name="DNode"></info>
    </data>
</root>

我想制作这个：

<root>
    <newnode id="C" order="1" name="CNode"></newnode>
    <newnode id="A" order="3" name="ANode"></newnode>
</root>

正如您所看到的，这个想法是通过检索相应的信息来“完成”id 的子集，并根据它们在<data>.

请注意，<data>它应该有很多子节点。

此外，我将带有<data>元素信息的节点与 id 的子集分开，因为我将有很多子集，并且我不想“到处”都有重复的信息。

提前致谢。

4

2 回答 2

2

交叉引用要求使用键：

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output indent="yes"/>

  <xsl:key name="k1" match="info" use="@id"/>

  <xsl:template match="root">
    <xsl:copy>
      <xsl:apply-templates select="subset/e">
        <xsl:sort select="key('k1', @id)/@order" data-type="number"/>
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="e">
    <newnode id="{@id}" order="{key('k1', @id)/@order}" name="{key('k1', @id)/@name}"/>
  </xsl:template>

</xsl:stylesheet>

这应该适用于您提供的输入样本。

于 2010-03-10T18:13:29.597 回答
1

您还可以关闭子集，具体取决于您可能需要对实际数据执行的操作。

<xsl:output indent="yes" />

<xsl:key name="subset" match="e" use="@id" />

<xsl:template match="/">
    <root>
    <xsl:for-each select="//info[count(key('subset',@id)[1]) &gt; 0]">
        <xsl:sort select="@order" data-type="number" />
        <newnode id="{@id}" order="{@order}" name="{@name}" />
    </xsl:for-each>
    </root>
</xsl:template>

于 2010-03-10T18:30:52.920 回答