6

我有一个连接到从 arduino 的 OPT101 来测量光强度。我想将从 OPT101 电路接收到的数据发送到主 arduino，它将在串行监视器上打印数据。当我测试我的代码时，屏幕上什么也没有显示。（我知道这不是我的 i2c 连接，因为我通过发送“hello”对其进行了测试）。我使用 arduino leonardo 作为奴隶，使用 arduino uno 作为主人。

OPT101 电路的代码是：

#define inPin0 0

void setup() {

  Serial.begin(9600);
  Serial.println();

}

void loop() {

  int pinRead0 = analogRead(inPin0);
  double pVolt0 = pinRead0 / 1024.00 * 5.0;
  Serial.print(pVolt0, 4 );
  Serial.println();

  delay(100);

}

我厌倦了结合从属代码和我的 OPT101 代码来得到这个：#include

#define inPin0 0

void setup() {

  Wire.begin(2);

}

void loop() {

  Wire.beginTransmission(2);
  Wire.onRequest(requestEvent);
  Wire.endTransmission();

}

void requestEvent()
{  
  int pinRead0 = analogRead(inPin0);
  int pVolt0 = pinRead0 / 1024.0 * 5.0;
  Wire.write((byte)pVolt0);
}

这是我的主代码：

#include <Wire.h>

void setup()
{

  Wire.begin();
  Serial.begin(14400);

  Wire.requestFrom(2, 8);

  while(Wire.available())
  {

    char c = Wire.read();
    Serial.print(c);
  }
}

void loop()
{
}
4

3 回答 3

5

您必须按照以下步骤在主 I2C 设备和从 I2C 设备之间进行通信：

  • 只有 master 可以发起读或写请求。
  • 读取或写入请求必须是同步的。这意味着，slave 只能在 master 请求它们之后返回数据，反之亦然。
  • 不要使用 0 - 7 的从机地址。它们是保留的。使用范围在 8 到 127 之间的从地址。
  • 在 Arduino I2C 上，您只能发送和接收一个字节。要发送或接收具有多个字节的整数、双精度，您需要先将它们拆分，另一方面，您必须将它们组合成等效的数据类型。（如我错了请纠正我。）

你的代码应该是这样的：

主草图：

#include <Wire.h>
#define SLAVE_ADDRESS 0x40

// This macro reads two byte from I2C slave and converts into equivalent int
#define I2C_ReadInteger(buf,dataInteger) \
    buf[0] = Wire.read(); \
    buf[1] = Wire.read(); \
    dataInteger = *((int *)buf);

// Returns light intensity measured by 'SLAVE_ADDRESS' device
int GetLightIntensity()
{
    byte Temp[2];
    int Result;

    // To get integer value from slave, two are required
    int NumberOfBytes = 2;

    // Request 'NumberOfBytes' from 'SLAVE_ADDRESS'
    Wire.requestFrom(SLAVE_ADDRESS, NumberOfBytes);

    // Call macro to read and convert bytes (Temp) to int (Result)
    I2C_ReadInteger(Temp, Result);

    return Result;
}

void setup()
{
    // Initiate I2C Master
    Wire.begin();

    // Initiate Serial communication @ 9600 baud or of your choice
    Serial.begin(9600);
}

void loop()
{
    // Print light intensity at defined interval
    Serial.print("Light Intensity = ");
    Serial.println(GetLightIntensity());

    delay(1000);
}


奴隶素描：

#include <Wire.h>
#define SLAVE_ADDRESS 0x40
#define inPin0 0

// Preapres 2-bytes equivalent to its int
#define IntegerToByte(buf,intData) \
  *((int *)buf) = intData;

// Sends int to Master
void I2C_SendInteger(int Data)
{
  byte Temp[2];

  // I2C can only send a byte at a time.
  // Int is of 2bytes and we need to split them into bytes
  // in order to send it to Master.
  // On Master side, it receives 2bytes and parses into
  // equvivalent int.
  IntegerToByte(Temp, Data);

  // Write 2bytes to Master
  Wire.write(Temp, 2);
}

void setup()
{
  // Initiate I2C Slave @ 'SLAVE_ADDRESS'
  Wire.begin(SLAVE_ADDRESS);

  // Register callback on request by Master
  Wire.onRequest(requestEvent);
}


void loop()
{
}

//
void requestEvent()
{  
  // Read sensor
  int pinRead0 = analogRead(inPin0);
  int pVolt0 = pinRead0 / 1024.0 * 5.0;

  // Send int to Master
  I2C_SendInteger(pVolt0);
}

此代码在 Arduino Version: 1.6.7上测试。有关 I2C 通信的更多信息，请参阅 Arduino 示例：主读卡器

于 2016-02-02T07:16:37.587 回答
1

为什么将while循环放在setup()函数中而不是使用loop()函数？

但更令人困惑的是这条线int pVolt0 = pinRead0 / 1024.0 * 5.0;。在初始代码中，变量不是intbut double。我建议您尝试使用原始行重新编码：double pVolt0 = pinRead0 / 1024.00 * 5.0;

然后才减少到int。

于 2015-01-12T21:25:07.430 回答
0

在 Arduino I2C 中，您只能发送和接收一个字节，需要将它们组合成等效的数据类型。

于 2020-07-24T02:12:30.297 回答