2

背景故事是这是一个旧的 ColdFusion 应用程序，它正在升级到 ColdFusion 11。我已经确定我现在看到的主题错误是因为 XSLT 1.0 处理器被允许忽略此错误并通过忽略 xsl 来“恢复” : 属性指令。（谢谢裁判迈克尔凯。）

我无法完全解决解决方案，所以这里有一些简化的代码：

XML

<?xml version="1.0" encoding="UTF-8"?>
<Organization>
    <Subscriber>
        <data>
            <struct>
                <var name='DEPENDENT'>
                    <array length='1'>
                        <struct>
                            <var name='PROVIDER'>
                                <struct>
                                    <var name='PROVIDERCODE'>
                                        <string>A4321</string>
                                    </var>
                                    <var name='TYPE'>
                                        <string>Primary Care Provider</string>
                                    </var>
                                </struct>
                            </var>
                        </struct>
                    </array>
                </var>
            </struct>
        </data>
    </Subscriber>
</Organization>

您可能会认为这是旧的WDDX 格式。下面的 XSLT 将这种丑陋的、深度嵌套的格式转换为更干净/更简单的 XML 格式。

XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:strip-space elements="*"/>
<xsl:template match="/">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="var">
    <xsl:choose>
        <xsl:when test="translate(@name, 'TEX', 'tex') = 'text'">
            <xsl:value-of select="./string"/>
        </xsl:when>
        <xsl:when test="translate(@name, 'TYPE', 'type') = 'type'">
            <xsl:attribute name="type">
                <xsl:value-of select="./string"/>
            </xsl:attribute>
        </xsl:when>        
        <xsl:when test="child::array">
            <xsl:apply-templates/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:element name="{translate(@name,'ABCDEFGHIJKLMNOPQRSTUVWXYZ','abcdefghijklmnopqrstuvwxyz')}">
                <xsl:apply-templates/>
            </xsl:element>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template match="struct">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="array">
    <xsl:param name="parentname" select="translate(../@name,'ABCDEFGHIJKLMNOPQRSTUVWXYZ','abcdefghijklmnopqrstuvwxyz')"/>
    <xsl:for-each select="struct">
        <xsl:element name="{$parentname}">
            <xsl:if test="./var[translate(@name, 'RELATIONSHPCD', 'relationshpcd') = 'relationshipcode']">
                <xsl:attribute name="relationshipcode"><xsl:value-of select="./var[translate(@name, 'RELATIONSHPCD', 'relationshpcd') = 'relationshipcode']"/></xsl:attribute>
            </xsl:if>
            <xsl:apply-templates/>
        </xsl:element>
    </xsl:for-each>
</xsl:template>

<xsl:template match="string|number">
    <xsl:value-of select="."/>
</xsl:template>

<xsl:template match="boolean">
    <xsl:value-of select="@value"/>
</xsl:template>

<xsl:template match="Subscriber">
    <subscriber>
        <xsl:apply-templates/>
    </subscriber>
</xsl:template>

<xsl:template match="Organization">
    <organization>
        <xsl:apply-templates/>
    </organization>
</xsl:template>
</xsl:stylesheet>

不幸的是，WDDX 名称属性的大小写不一致，因此翻译命令可以解决这个问题，不幸的是，这使代码更复杂一些。

预期输出

<?xml version="1.0" encoding="UTF-8"?>
<organization>
    <subscriber>
        <dependent>
            <provider type="Primary Care Provider">
                <providercode>A4321</providercode>
            </provider>
        </dependent>
    </subscriber>
</organization>

问题

问题在于，在上面的示例中，可能会在遇到“type”节点之前将“providercode”添加到“provider”节点，导致无法在包含的子节点之后创建“属性节点”元素“错误.o

请注意，为了清楚起见，我已经简化了上面的示例。大约有六个具有特定“名称”属性的“var”节点应该作为属性插入，而其他简单的节点则直接作为节点添加。

任何有关如何解决此问题的帮助将不胜感激。

提前致谢。

保罗

4

2 回答 2

2

不幸的是，WDDX 名称属性的大小写不一致，因此翻译命令可以解决这个问题，不幸的是，这使代码更复杂一些。

太糟糕了，您没有将这个（和其他非必需品）从您的示例中删除 - 请参阅：https ://stackoverflow.com/help/mcve

IIUC，类似以下的内容可以解决您的问题。这个想法是在创建子级的模板之前应用创建属性的模板。

...
<xsl:template match="var[not(@name='TYPE')]">
    <xsl:choose>
        <xsl:when test="translate(@name, 'TEX', 'tex') = 'text'">
            <xsl:value-of select="./string"/>
        </xsl:when>
        <xsl:when test="child::array">
            <xsl:apply-templates/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:element name="{translate(@name,'ABCDEFGHIJKLMNOPQRSTUVWXYZ','abcdefghijklmnopqrstuvwxyz')}">
                <xsl:apply-templates select="struct/var[@name='TYPE']"/>
                <xsl:apply-templates/>
            </xsl:element>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template match="var[@name='TYPE']">
    <xsl:attribute name="type">
        <xsl:value-of select="./string"/>
    </xsl:attribute>
</xsl:template>

<xsl:template match="struct">
    <xsl:apply-templates select="var[not(@name='TYPE')]"/>
</xsl:template> 
...
于 2014-06-11T02:16:13.903 回答
0

下面的样式表基于您提供的最小示例和您提到的一些要求（属性名称不一致的情况）。我不确定这是否足以处理你的真实世界文件，但它可能会以某种方式帮助你，并可能给你一些想法。

我使用了三个模板来处理var元素，基于它包含的后代类型（array或struct）string，以及一些谓词测试一些属性值（例如providercode）。如果应用于您提供的最小示例，它将生成您期望的结果。您可能需要进行一些调整以使其适应您的实际问题。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:variable name="lower">abcdefghijklmnopqrstuvwxyz</xsl:variable>
    <xsl:variable name="upper">ABCDEFGHIJKLMNOPQRSTUVWXYZ</xsl:variable>

    <xsl:template match="/">
        <organization>
            <subscriber>
                <xsl:apply-templates select="Organization/Subscriber/data/struct/var"/>
            </subscriber>
        </organization>
    </xsl:template>

    <xsl:template match="var[array]">
        <xsl:element name="{translate(@name,$upper,$lower)}">
            <xsl:apply-templates select="array/struct/var"/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="var[struct]">
        <xsl:element name="{translate(@name,$upper,$lower)}">
            <xsl:attribute name="type">
                <xsl:value-of select="struct/var[translate(@name,$upper,$lower)='type']/string"/>
            </xsl:attribute>
            <xsl:apply-templates select="struct/var"/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="var[string][translate(@name,$upper,$lower) = 'providercode']">
        <xsl:element name="{translate(@name,$upper,$lower)}">
            <xsl:value-of select="string"/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="string"/>
</xsl:stylesheet>

我将lower和声明upper为变量，因此使用该translate()函数将字符串转换为小写会更容易。

您可以在此 XSLT fiddle中试用此代码，进行实验并查看转换结果。

于 2014-06-11T02:29:49.933 回答