5

如何设置自定义堆栈大小TThread？我正在尝试重新引入 的构造函数，TThread但它说ThreadProc缺少但它就在System.Classes.

type
  TThreadHelper = class helper for TThread
    constructor Create(const CreateSuspended: Boolean = False; const StackSize: Integer = 0); reintroduce;
 end;

{ TThreadHelper }

constructor TThreadHelper.Create(const CreateSuspended: Boolean; const StackSize: Integer);
begin
  Self.FSuspended := not Self.FExternalThread;
  Self.FCreateSuspended := CreateSuspended and not Self.FExternalThread;
  if not Self.FExternalThread then
  begin
    Self.FHandle := BeginThread(nil, StackSize, @ThreadProc, Pointer(Self), CREATE_SUSPENDED, Self.FThreadID);
    if Self.FHandle = 0 then
    raise EThread.CreateResFmt(@SThreadCreateError, [SysErrorMessage(GetLastError)]);
  end
  else
  begin
    Self.FHandle := Winapi.Windows.GetCurrentThread;
    Self.FThreadId := GetCurrentThreadId;
  end;
end;

[dcc32 错误] Project5.dpr(29)：E2003 未声明的标识符：'ThreadProc'

4

4 回答 4

7

我不知道，是否可以在创建线程后设置堆栈大小。也许SetThreadStackGuarantee会有帮助？

您可以使用 来从头开始创建线程BeginThread，但这非常复杂。我在这里有一个解决方法，方法是使用Detours. 请注意，有几种Detours变体。我认为只有Cromis.Detoursx64 兼容。

unit IndividualStackSizeForThread;

interface

uses 
  System.Classes,
  Cromis.Detours { http://www.cromis.net/blog/downloads/cromis-ipc/ };

type
  TThreadHelper = class helper for TThread
    constructor Create(CreateSuspended: Boolean; StackSize: LongWord);
 end;

implementation

var
  TrampolineBeginThread: function(SecurityAttributes: Pointer; StackSize: LongWord;
    ThreadFunc: TThreadFunc; Parameter: Pointer; CreationFlags: LongWord; 
    var ThreadId: TThreadID): THandle = nil;

threadvar
  StackSizeOverride: LongWord;

function InterceptBeginThread(SecurityAttributes: Pointer; StackSize: LongWord;
  ThreadFunc: TThreadFunc; Parameter: Pointer; CreationFlags: LongWord;
  var ThreadId: TThreadID): THandle;
const
  STACK_SIZE_PARAM_IS_A_RESERVATION = $00010000; // http://msdn.microsoft.com/en-us/library/windows/desktop/ms682453(v=vs.85).aspx
begin
  if StackSizeOverride <> 0 then
  begin
    CreationFlags := CreationFlags or STACK_SIZE_PARAM_IS_A_RESERVATION;
    StackSize := StackSizeOverride;
    StackSizeOverride := 0;
  end;

  Result := TrampolineBeginThread(SecurityAttributes, StackSize, ThreadFunc, 
    Parameter, CreationFlags, ThreadId);
end;

constructor TThreadHelper.Create(CreateSuspended: Boolean; StackSize: LongWord);
begin
  StackSizeOverride := StackSize;
  inherited Create(CreateSuspended);
end;

initialization

TrampolineBeginThread := InterceptCreate(@BeginThread, @InterceptBeginThread);

finalization

InterceptRemove(@TrampolineBeginThread, @InterceptBeginThread);

end.

我不知道为什么 Embt 不允许程序员指定堆栈大小，如果有人知道原因，我会很感兴趣。

于 2014-06-10T12:22:58.867 回答
3

根本没有办法使用TThread. 无论出于何种原因，设计者TThread未能在TThread. 这显然是一个遗漏。你应该打电话BeginThread或CreateThread直接打电话。

如果您只是不顾一切地想让您的 hack 工作，那么您需要找到在 单元ThreadProc的实现部分中声明的函数的地址Classes。一些可能的方法：

  1. 在运行时反汇编TThread.Create以读出ThreadProc.
  2. 创建一个虚拟线程，查看其调用堆栈以查找ThreadProc.
  3. BeginThread使用绕道钩。创建一个虚拟线程。注意传递的线程过程的地址。那就是ThreadProc。

这种黑客攻击的一个很好的想法来源是madExcept.

另一种应用 hack 的方法是在BeginThread. 然后，您可以使用线程局部变量来提供堆栈大小。该线程局部变量的值high(LongWord)意味着“使用作为参数传递的值”，任何其他值都是 detoured 使用的值BeginThread。

于 2014-06-10T12:05:00.997 回答
3

正如大卫指出的那样，您无法控制使用TThread类创建的线程的堆栈大小。您必须使用BeginThread或自己创建实际线程CreateThread。

但是，如果您不需要为应用程序中的每个线程设置不同的堆栈大小：那么您可以使用Min stack size和Max stack size
的链接选项设置默认堆栈大小。

在项目选项中设置选项，或使用指令：{$M minstacksize,maxstacksize} {$MINSTACKSIZE number} {$MAXSTACKSIZE number}

于 2014-06-10T13:12:54.007 回答
3

对于 Delphi 10.3 RIO 及更高版本，现在有一个重载的构造函数，允许您在 Windows 平台上为 TThread 设置 ReservedStackSize。

{$IF Defined(MSWINDOWS)}
    constructor Create(CreateSuspended: Boolean; ReservedStackSize: NativeUInt); overload;
{$ENDIF MSWINDOWS}
于 2020-05-08T17:13:21.420 回答