5

我试图找到一些comonad的实际应用，我想我会尝试看看我是否可以将经典的Wumpus世界表示为comonad。

我想用这段代码让 Wumpus 在世界上左右移动，清理脏瓷砖，避免坑。似乎唯一有用的comonad函数是提取（获取当前图块），并且无法使用移动和清洁图块来使用扩展或复制。

我不确定comonads 是否合适，但我看过一个演讲（Dominic Orchard: A Notation for Comonads），其中comonads 用于在二维矩阵中对光标进行建模。

如果comonad 是代表Wumpus 世界的好方法，您能否说明我的代码哪里出错了？如果错了，你能建议一个简单的comonads应用吗？

module Wumpus where

-- Incomplete model of a world inhabited by a Wumpus who likes a nice
-- tidy world but does not like falling in pits.

import Control.Comonad

-- The Wumpus world is made up of tiles that can be in one of three
-- states.
data Tile = Clean | Dirty | Pit
  deriving (Show, Eq)

-- The Wumpus world is a one dimensional array partitioned into three
-- values: the tiles to the left of the Wumpus, the tile occupied by
-- the Wumpus, and the tiles to the right of the Wumpus.
data World a = World [a] a [a]
  deriving (Show, Eq)

-- Applies a function to every tile in the world
instance Functor World where
  fmap f (World as b cs) = World (fmap f as) (f b) (fmap f cs)

-- The Wumpus world is a Comonad
instance Comonad World where
  -- get the part of the world the Wumpus currently occupies
  extract (World _ b _) = b
  -- not sure what this means in the Wumpus world.  This type checks
  -- but does not make sense to me.
  extend f w@(World as b cs) = World (map world as) (f w) (map world cs)
      where world v = f (World [] v [])

-- returns a world in which the Wumpus has either 1) moved one tile to
-- the left or 2) stayed in the same place if the Wumpus could not move
-- to the left.
moveLeft :: World a -> World a
moveLeft w@(World [] _ _) = w
moveLeft (World as b cs) = World (init as) (last as) (b:cs)

-- returns a world in which the Wumpus has either 1) moved one tile to
-- the right or 2) stayed in the same place if the Wumpus could not move
-- to the right.
moveRight :: World a -> World a
moveRight w@(World _ _ []) = w
moveRight (World as b cs) = World (as ++ [b]) (head cs) (tail cs)

initWorld = World [Dirty, Clean, Dirty] Dirty [Clean, Dirty, Pit]

-- cleans the current tile
cleanTile :: Tile -> Tile
cleanTile Dirty = Clean
cleanTile t = t

谢谢！

4

1 回答 1

7

我会将我的一连串评论移至更连贯的答案..

你所拥有的实际上是一个“拉链”，特别是一个列表的拉链

data ListZip a = ListZip {lefts   :: [a]
                         ,focus   ::  a
                         ,rights  :: [a]}

我们可以将非空列表转换为ListZip

toZip :: [a] -> Maybe (ListZip a)
toZip (x:xs) = Just $ ListZip [] x xs
toZip  _     = Nothing

像所有拉链一样，ListZip有一个重点，我们可以在这个重点领域开展工作

modifyFocus :: (a -> a) -> ListZip a -> ListZip a
modifyFocus f z = z{focus = f $ focus z}

我们可以将焦点转移到你所说的moveLeft和moveRight

moveLeft, moveRight :: ListZip a -> ListZip a

moveLeft  (ListZip (x:xs) y ys) = ListZip xs x (y : ys)
moveRight (ListZip xs x (y:ys)) = ListZip (x : xs) y ys

现在像所有拉链一样，ListZip是一个comonad！

extract提取焦点，或当前占据的方格

instance Comonad ListZip where
  extract = focus

并extend返回一个新世界，我们根据“规则”修改了每个焦点方块。

  extend f w = ListZip (moving moveLeft) (f w) (moving moveRight)
    where moving i = map f $ iterate i w

在这种情况下，规则是一个函数

ZipList a -> a

如果这让您隐约想起元胞自动机，那您是对的！这与 Conway 的 Game of Life 等游戏的运作方式非常相似：简单的上下文相关规则。

我们还duplicate定义了将返回一个ListzipofListZip的位置，其中焦点已在每个可能的方向上移动ListZip。

现在我不知道这在 Wumpus 的上下文中到底有什么用，你可以对板上的每个方块进行任何统一的转换吗？您能否从能够将 Wumpus 世界具体化为所有可能的 Wumpus 世界的 Wumpus 世界中受益？

这就是comonads在这种情况下给你的。

于 2014-06-06T04:32:07.593 回答