9

对于我的另一个答案，我编写了以下代码，为 enumerable提供了对角遍历 的实例（它从那里的版本略有更新，但使用相同的逻辑）：UniverseGeneric

{-# LANGUAGE DeriveGeneric, TypeOperators, ScopedTypeVariables #-}
{-# LANGUAGE FlexibleInstances, FlexibleContexts, DefaultSignatures #-}
{-# LANGUAGE UndecidableInstances, OverlappingInstances #-}

import Data.Universe
import Control.Monad.Omega
import GHC.Generics
import Control.Monad (mplus, liftM2)

class GUniverse f where
    guniverse :: Omega (f x)

instance GUniverse U1 where
    guniverse = return U1

instance (Universe c) => GUniverse (K1 i c) where
    guniverse = fmap K1 $ each (universe :: [c])        -- (1)

instance (GUniverse f) => GUniverse (M1 i c f) where
    guniverse = fmap M1 (guniverse :: Omega (f p))

instance (GUniverse f, GUniverse g) => GUniverse (f :*: g) where
    guniverse = liftM2 (:*:) ls rs
        where ls = (guniverse :: Omega (f p))
              rs = (guniverse :: Omega (g p))

instance (GUniverse f, GUniverse g) => GUniverse (f :+: g) where
    guniverse = (fmap L1 $ ls) `mplus` (fmap R1 $ rs)   -- (2)
        where ls = (guniverse :: Omega (f p))
              rs = (guniverse :: Omega (g p))

instance (Generic a, GUniverse (Rep a)) => Universe a where
    universe = runOmega $ fmap to $ (guniverse :: Omega (Rep a x))

（Omega可能与问题无关，但是问题的一部分。）

这适用于大多数类型，甚至是递归类型：

data T6 = T6' | T6 T6 deriving (Show, Generic)
data T = A | B T | C T T deriving (Show, Generic)
data Tree a = Leaf a | Branch (Tree a) (Tree a) deriving (Show, Generic, Eq)

例子：

*Main> take 5 $ (universe :: [T6])
[T6',T6 T6',T6 (T6 T6'),T6 (T6 (T6 T6')),T6 (T6 (T6 (T6 T6')))]
*Main> take 5 $ (universe :: [T])
[A,B A,B (B A),C A A,B (B (B A))]
*Main> take 5 $ (universe :: [Tree Bool])
[Leaf False,Leaf True,Branch (Leaf False) (Leaf False),Branch (Leaf False) (Leaf True),Branch (Leaf True) (Leaf False)]

但请注意，上述类型都不是一开始就有递归构造函数！事实上（这就是问题所在），存在以下分歧：

*Main> data T7 = T7 T7 | T7' deriving (Show, Generic)
*Main> take 5 $ (universe :: [T7])
*** Exception: <<loop>>

我首先认为可能有一些与Omegas' 的评估顺序有关的东西，但是将左右部分交换成行(2)只会T7起作用，而T6失败，这是我所期望的正确行为。

我目前的怀疑是对universein line的调用(1)评估得太早了。例如，以下也有分歧，而列表中应该只有一个值，甚至不应该评估：

*Main> data T8 = T8 T8  deriving (Show, Generic)
*Main> null $ (universe :: [T8])
*** Exception: <<loop>>

因此，唯一的实例 ,在 list 中T8 (T8 (...) ... )被评估，即使它不是必需的！我不知道这个效果是从哪里来的——它是递归使用它自己的实例吗？但是，为什么“右递归”类型的行为正确，而“左递归”类型 ( ) 却没有呢？UniverseT6T7

这是一个严格的问题吗？如果是这样，在代码的哪一部分？我的Universe实例？Generic? 以及如何解决？如果这很重要，我使用 GHC 7.6.3。

4

1 回答 1

0

像这样的类型T8无法生成。让我们看看 T8 的 Universe 的泛型版本实际上简化为：

t8Universe :: [T8]
t8Universe = fmap T8 t8Universe

绝不会产生 (:) 或 []。如果没有另一个非递归构造函数来成功生成，就无法取得进展。t8Universe有和有一样多的元素t8Universe，但这是循环的，所以评估循环。

于 2015-09-07T20:55:23.150 回答