9

有任何想法吗？为什么我得到：0x00400020 处的运行时异常：获取地址未在字边界 0x00000007 上对齐问题行是：lw $s1,0($a1) #copy arg2 = size of array

.data
    .align 4 #added this, didnt work
    size:   .word   7
    .align 4 #added this, didnt work
    search: .word   30
    .align 4 #added this,didnt work
    array:  .word 10,20,30,40,50,60,70
    .align 4

.text

main:

            la  $a0,array   #$a0 = address of array
            lw  $a1,size    #a1 = size of array
            lw  $a2,search  #$a2 = search key


COUNT:
            lw $s0,0($a0)   #copy arg1 = address array
            addi $s1,$zero,7
            lw $s1,0($a1)   #copy arg2 = size of array
            lw $s2,0($a2)   #copy arg3 = search key (n)
            addi $s2,$zero,30
            COUNTLOOP:
            add $v0,$zero,$zero #v0 = res
            add $t0,$zero,$zero #$t0 = init i to 0
            slt $t1,$t0,$s1     #check if i > size of array
            beq $t1,$zero,DONECOUNT #i is n so end
            sll $t2,$s0,2       #$t2 = get off set for a[i]
            lw  $t3,0($t2)      #$t3 = get value of a[i]
            bne $t3,$s2,CLOOPBTM #check if a[i] == seach key
            addi $v0,$v0,1      #if above then increment res
            CLOOPBTM:
            addi $t0,$t0,1
            j COUNTLOOP
            DONECOUNT:
4

1 回答 1

8

代码的问题是，您使用的不是存储大小的地址，而是大小本身：

在这里，您将地址加载到 A0 并将大小 (7) 加载到 A1：

        la  $a0,array   
        lw  $a1,size    #a1 = size of array

在这里，您加载存储在数组中的第一个单词（将加载 10）。这不是你的本意。

        lw $s0,0($a0)   #copy arg1 = address array
        addi $s1,$zero,7

在这里，您加载存储在位置 0x000007 的第一个单词。（您的尺码）。这也可能不是有意的，并且会导致异常，因为地址未对齐：

        lw $s1,0($a1)   #copy arg2 = size of array

等等。

在我看来，您误解了 LW 指令的作用。它将内存位置读入寄存器。您在循环的序言中想要的是制作寄存器的副本。

为此，如果您的汇编程序支持，您可以使用 move 伪指令。否则使用 OR 指令复制寄存器，如下所示：

COUNT:
            or    $s0, $a0, $a0   #copy arg1 = address array
            addi  $s1, $zero,7
            or    $s1, $a1, $a1   #copy arg2 = size of array
            or    $s2, $a2, $a2   #copy arg3 = search key (n)
            addi  $s2, $zero,30
            COUNTLOOP:

            ...

有关线性搜索循环的完整示例，请尝试此（未经测试并期望汇编程序关心延迟槽）

main:

            la  $a0,array            # $a0 = address of array
            lw  $a1,size             # $a1  = size of array
            lw  $a2,search           # $a2 = search key


            beq $a1, $zero, NOTFOUND # handle the size==0 case..
            or  $v0, $zero, $zero    # init counter to zero

LOOP:
            lw  $s0, 0($a0)          # load element
            beq $s0, $a2, FOUND      # branch if key found:

            addiu $a0, $a0, 4        # increment array pointer
            addiu $v0, $v0, 1        # increment loop counter
            bne   $v0, $a1, LOOP     # repeat until we've processed the array.

NOTFOUND:
            # --------------------------------------
            # if you reach this, key does not exist:
            # --------------------------------------
            li  $v0, -1              # load a -1 to signal key not found.
            jr  $lr                  # return to caller

FOUND:
            # -----------------------------------------
            # v0 now contains the position of the key.
            # -----------------------------------------
            jr  $lr
于 2010-02-26T04:37:18.380 回答