1

好的，我正在努力做到这一点，以便当用户启动我的空中应用程序时，它会自行定位并调整自身大小，使其与上次打开时的大小一致。

这是我的代码：

private function init():void
{
    gotoLastPosition();
    this.nativeWindow.addEventListener( Event.CLOSING, saveAppPosition );
}

private function saveAppPosition(e:Event = null):void
{
    var xml:XML = new XML('<position x="'+this.nativeWindow.x+'" y="'+this.nativeWindow.y+'" width="'+this.width+'" height="'+this.height+'"/>');

    var f:File = File.applicationStorageDirectory.resolvePath("appPosition.xml");
    var s:FileStream = new FileStream();
    try
    {
        s.open(f,flash.filesystem.FileMode.WRITE);

        s.writeUTFBytes(xml.toXMLString());

        s.close();
    }
    catch(e:Error){}
}

private function gotoLastPosition():void
{
    var f:File = File.applicationStorageDirectory.resolvePath("appPosition.xml");   
    if(f.exists)
    {
        var s:FileStream = new FileStream();
        s.open(f,flash.filesystem.FileMode.READ);
        var xml:XML = XML(s.readUTFBytes(s.bytesAvailable));

        this.nativeWindow.x = xml.@x;
        this.nativeWindow.y = xml.@y;
        this.width = xml.@width;
        this.height = xml.@height;
    }
}

这确实有效，但是，我收到用户的抱怨，有时当他们启动应用程序时，找不到它的位置（屏幕外），他们可以右键单击任务栏项目并将其最大化以将其取回，但这应该没有必要。

我只能假设这个问题是由我试图保存应用程序的位置引起的。我不知道可能出了什么问题，或者我该如何解决这个问题？

也许是一种在定位后判断应用程序是否在屏幕外的方法，如果是，则将其移动到屏幕上？不知道我该怎么做？

有任何想法吗？

谢谢！！！

4

1 回答 1

3

我相信您会希望从以下位置更改您的 XML 保存代码：

try
{
    s.open(f,flash.filesystem.FileMode.WRITE);

    s.writeUTFBytes(xml.toXMLString());

    s.close();
}
catch(e:Error){}

到

try
{
    s.open(f,flash.filesystem.FileMode.WRITE);
    s.writeUTFBytes(xml.toXMLString());
} catch(e:Error) {
    logger.error( e );
} finally {
    s.close();
}

如果发生错误，您将永远看不到它，因为 catch 块只是忽略它。如果某些人发生错误，则永远不会写入流。此外，关闭调用也永远不会执行，因此文件保持打开状态。将 close() 调用放在 finally 块中将确保无论成功或失败，文件都会关闭。不能保证这是您的问题，但从理论上讲，这些是某些用户可能遇到的潜在陷阱。

此外，您可能还想在阅读后关闭文件。

var s:FileStream = new FileStream();
try {
   s.open(f,flash.filesystem.FileMode.READ);
   var xml:XML = XML(s.readUTFBytes(s.bytesAvailable));
   ...
} finally {
   s.close();
}

它可能无法在退出时保存窗口位置，因为它无法打开文件进行写入，因为它仍然可以打开以进行读取。

我还建议开始将这些错误写入日志文件，以查看错误是否是罪魁祸首。AIR 有一个非常好的日志系统，您可以使用它与 log4j 非常相似。当人们遇到麻烦时，您可以让他们向您发送该日志文件，并获得有关他们的程序中发生的情况的更好反馈。必须登录任何严肃的应用程序。

更不用说您可以使用 XPanelOnAIR 之类的应用程序在调试期间获取日志消息。比 trace() 好得多。

http://www.novio.be/blog/?p=920

http://livedocs.adobe.com/flex/3/html/help.html?content=logging_09.html

删除了对 flush() 的引用，因为 AIR 没有这些调用。

于 2010-02-25T17:58:27.460 回答