-1

我正在重构以前使用 opengl 1.1 的物理模拟器，现在我将其设置为使用 VBO 和 GLSL 着色器。目前，模拟中的粒子都是从 VBO 中绘制的，而物理边界是使用 opengl 即时模式绘制的。（我知道即时模式不是最终解决方案，但升级它是另一次）

问题： 经过测试，我发现在 ATI 卡上没有绘制边界。我建立了一个简单的测试项目来弄清楚发生了什么，我看到的结果与我的主项目相同：

在这种情况下，我可以绘制 VBO 对象，佛像，当我禁用着色器时，我可以在立即模式下绘制。但是当我尝试使用即时模式将三角形放在“3d”空间中时，它不会只在 ATI 上渲染。

ATI 渲染 http://s23.postimg.org/xcgjxl2h7/ATI.png

Nvidia 渲染 http://s23.postimg.org/qaimbdyvf/NVIDIA.png

所以白色三角形是我使用的时候

glUseProgram(0);
glBegin(GL_TRIANGLES);
    glVertex3f(-0.9, 1, -1.0);
    glVertex3f(-0.9, -1, -1.0);
    glVertex3f(-0.2, 1, -1.0);
glEnd();

红色三角形是

glUseProgram(shaderProgramPrimID);
glBegin(GL_TRIANGLES);
    glVertex3f(0.9, 1, -1.0);
    glVertex3f(0.9, -1, -1.0);
    glVertex3f(0.2, 1, -1.0);
glEnd();

佛是glDrawElements召唤

相关着色器：VertexShaderPrim

#version 130

in vec4 s_vPosition;
in vec4 s_vColor;
out vec4 color;

void main () {
    color = s_vColor;
    gl_Position = s_vPosition;
}

FragmentShaderPrim

#version 130

in vec4 color;
out vec4 fColor;

void main () {
    fColor = color;
}

顶点着色器

#version 130

in vec4 s_vPosition;    
in vec4 s_vNormal;      

uniform mat4 mM;        
uniform mat4 mV;        
uniform mat4 mP;        
uniform mat4 mRotations;

uniform vec4 vLight;    

out vec3 fN;        
out vec3 fL;        

out vec3 fE;        

void main () {
    fN = (mRotations*s_vNormal).xyz;    
    fL = (vLight).xyz;              
    fE = (mV*mM*s_vPosition).xyz;   
    gl_Position = mP*mV*mM*s_vPosition;
}

片段着色器

#version 130

in vec3 fN;
in vec3 fL;
in vec3 fE;     

out vec4 fColor;

void main () {
    vec3 N = normalize(fN);
    vec3 L = normalize(fL);

    vec3 E = normalize(-fE);
    vec3 H = normalize(L + E);      

    float diffuse_intensity = max(dot(N, L), 0.0);
    vec4 diffuse_final = diffuse_intensity*vec4(0.1, 0.1, 0.1, 1.0);

    float spec_intensity = pow(max(dot(N, H), 0.0), 30);
    vec4 spec_final = spec_intensity*vec4(0.9, 0.1, 0.1, 1.0);

    fColor = diffuse_final + spec_final;
}
4

1 回答 1

1

NVIDIA 以在顶点属性方面做一些不应该做的事情而闻名。在这种情况下，您正在利用顶点属性别名，这实际上违反了 GLSL 规范。

如果您打算使用固定功能的顶点属性，请不要按照您的方式编写着色器。使用glVertexAttrib* (0, ....)或使用gl_Vertex而不是通用顶点属性（例如s_vPosition）。

即使顶点属性0通常别名为gl_Vertex，您仍依赖未定义的行为来分配in s_vPosition给属性槽0。根本无法保证这会发生。s_vColor可以分配给0，特别是因为某些 GLSL 实现会在自动分配位置之前按字母顺序重新排列属性变量。

底线是您不应该像现在这样使用固定功能的顶点属性。我建议要么使用显式的通用属性并绑定着色器中的属性位置，要么简单地使用gl_Vertex,gl_Color等而不是通用属性。

于 2014-04-23T17:48:54.727 回答