1

我有一个 Flex 应用程序，它允许用户编辑基于云的文档。（想想 SlideRocket。）当用户试图离开或关闭浏览器窗口时，如果他们有未保存的更改，我想向他们显示一个你确定的对话框。

我正在使用以下自定义类，我在Flash player notify on browser close or change page (as3)中找到了该类。我不认为这是问题所在。

package
{
    import flash.external.ExternalInterface;

    public class ExternalInterfaceUtil
    {
        public static function addExternalEventListener(qualifiedEventName:String, callback:Function, callBackAlias:String):void
        {
                // 1. Expose the callback function via the callBackAlias
                ExternalInterface.addCallback( callBackAlias, callback );

                // 2. Build javascript to execute
                var jsExecuteCallBack:String = "document.getElementsByName('"+ExternalInterface.objectID+"')[0]."+callBackAlias+"()";
                var jsBindEvent:String = "function(){"+qualifiedEventName+"= function(){"+jsExecuteCallBack+"};}";

                // 3. Execute the composed javascript to perform the binding of the external event to the specified callBack function
                ExternalInterface.call(jsBindEvent);
        }
    }
}

在我的 applicationComplete 函数中，我向 javascript window.onbeforeunload 事件添加了一个事件侦听器，如下所示：

ExternalInterfaceUtil.addExternalEventListener("window.onbeforeunload", requestUnloadConfirmation, "unloadConfirmation");

当用户尝试关闭浏览器窗口时，会成功调用 Actionscript 函数 requestUnloadConfirmation（如下）。但是，它不会阻止浏览器关闭。（在 Chrome 中，浏览器关闭，随后调用 Actionscript 函数。在 Firefox 中，浏览器在函数执行期间保持打开状态，但随后关闭。）

private function requestUnloadConfirmation():String {
    if (changedSinceSave)
        return "There are unsaved changes. Are you sure you want to leave without saving?";
    else
        return null;
}

调试和发布版本以及生产服务器和本地机器上的行为都是相同的。

任何帮助将不胜感激，

戴夫

4

3 回答 3

2

现在，当 JavaScript 事件被触发时，它被设置为在您的 AS3 代码中调用您的函数，它确实如此。但是，JavaScript 函数不会返回您的 AS3 函数返回的值。要获得此行为，请将“return”添加到创建的 JavaScript 事件处理函数中，addExternalEventListener如下所示：

var jsBindEvent:String = "function(){"+qualifiedEventName+"= function(){return "+jsExecuteCallBack+"};}";

由于事件处理程序应该返回一个真或假值，你的requestUnloadConfirmation函数应该有一个返回类型Boolean并返回false以取消事件，true否则。使用以下命令获取确认对话框：

private function requestUnloadConfirmation():Boolean {          
    if (changedSinceSave)          
        return ExternalInterface.call("confirm", "There are unsaved changes. Are you sure you want to leave without saving?");
    else          
        return false;          
}

更新： 事实证明，将字符串返回到 window.onbeforeunload 会导致自动显示确认对话框。用于确认的 ExternalInterface.call 会导致显示第二个对话框；这是多余的。AS3 代码中唯一需要的更改是在生成的 JavaScript 中添加“return”。

于 2010-02-24T20:21:48.270 回答
0

在常规的 html/javascript 网络应用程序中，您将使用 window.onbeforeunload 事件来执行此操作。

http://www.4guysfromrolla.com/demos/OnBeforeUnloadDemo1.htm

也许您可以使用此事件，并检查您的 flex 应用程序的某些值以确定您是否应该询问用户（不熟悉 flex...）？

于 2010-02-24T09:12:30.140 回答
0

我必须在上面的代码中进行一些修改才能使其工作。问题是由于处理事件 window.onbeforeunload 的函数不应返回任何值以避免弹出确认，并且应在弹出确认有序时返回文本值

这是我的更改：

private function requestUnloadConfirmation():String {          
             if (changedSinceSave){
                    return "There are unsaved changes. Are you sure you want to leave without saving?";
             } 
            return null;          
        }

以及嵌入式 JS 的一点变化

var jsBindEvent:String = "function(){"+qualifiedEventName+"= function(){ if ("+jsExecuteCallBack+") return "+jsExecuteCallBack+"};}";
于 2015-05-19T13:30:36.017 回答