我需要使用 MS 批处理文件将程序的输出分配给变量。
所以在 GNU Bash shell 中我会使用VAR=$(application arg0 arg1). 我需要使用批处理文件在 Windows 中进行类似的行为。
类似的东西set VAR=application arg0 arg1。
问问题
369635 次
10 回答
480
一种方法是：
application arg0 arg1 > temp.txt
set /p VAR=<temp.txt
另一个是：
for /f %%i in ('application arg0 arg1') do set VAR=%%i
请注意，first %in%%i用于转义%后面的内容，并且在批处理文件而不是命令行中使用上述代码时需要。想象一下，你test.bat有类似的东西：
for /f %%i in ('c:\cygwin64\bin\date.exe +"%%Y%%m%%d%%H%%M%%S"') do set datetime=%%i
echo %datetime%
于 2010-02-26T07:13:44.917 回答
77
作为对这个先前答案的补充，管道可以在 for 语句中使用，由插入符号转义：
for /f "tokens=*" %%i in ('tasklist ^| grep "explorer"') do set VAR=%%i
于 2013-10-18T07:11:42.980 回答
10
@OP，如果它输出的不是数字，您可以使用for 循环来捕获程序的返回状态
于 2010-02-24T02:47:30.607 回答
10
执行for /f %%i in ('application arg0 arg1') do set VAR=%%i时：我收到错误：此时 %%i 出乎意料。作为修复，我必须在上面执行for /f %i in ('application arg0 arg1') do set VAR=%i
于 2016-12-07T11:14:52.807 回答
9
您可以使用批处理宏来简单地捕获命令输出，有点像 bash shell 的行为。
宏的用法很简单，看起来像
%$set% VAR=application arg1 arg2
它甚至适用于管道
%$set% allDrives="wmic logicaldisk get name /value | findstr "Name""
宏像数组一样使用变量并将每一行存储在单独的索引中。
在示例%$set% allDrives="wmic logicaldisk中将创建以下变量：
allDrives.Len=5
allDrives.Max=4
allDrives[0]=Name=C:
allDrives[1]=Name=D:
allDrives[2]=Name=F:
allDrives[3]=Name=G:
allDrives[4]=Name=Z:
allDrives=<contains the complete text with line feeds>
要使用它，了解宏本身的工作原理并不重要。
完整的例子
@echo off
setlocal
call :initMacro
%$set% ipOutput="ipconfig"
call :ShowVariable ipOutput
echo First line is %ipOutput[0]%
echo(
%$set% driveNames="wmic logicaldisk get name /value | findstr "Name""
call :ShowVariable driveNames
exit /b
:ShowVariable
setlocal EnableDelayedExpansion
for /L %%n in (0 1 !%~1.max!) do (
echo %%n: !%~1[%%n]!
)
echo(
exit /b
:initMacro
if "!!"=="" (
echo ERROR: Delayed Expansion must be disabled while defining macros
(goto) 2>nul
(goto) 2>nul
)
(set LF=^
%=empty=%
)
(set \n=^^^
%=empty=%
)
set $set=FOR /L %%N in (1 1 2) dO IF %%N==2 ( %\n%
setlocal EnableDelayedExpansion %\n%
for /f "tokens=1,* delims== " %%1 in ("!argv!") do ( %\n%
endlocal %\n%
endlocal %\n%
set "%%~1.Len=0" %\n%
set "%%~1=" %\n%
if "!!"=="" ( %\n%
%= Used if delayed expansion is enabled =% %\n%
setlocal DisableDelayedExpansion %\n%
for /F "delims=" %%O in ('"%%~2 | findstr /N ^^"') do ( %\n%
if "!!" NEQ "" ( %\n%
endlocal %\n%
) %\n%
setlocal DisableDelayedExpansion %\n%
set "line=%%O" %\n%
setlocal EnableDelayedExpansion %\n%
set pathExt=: %\n%
set path=; %\n%
set "line=!line:^=^^!" %\n%
set "line=!line:"=q"^""!" %\n%
call set "line=%%line:^!=q""^!%%" %\n%
set "line=!line:q""=^!" %\n%
set "line="!line:*:=!"" %\n%
for /F %%C in ("!%%~1.Len!") do ( %\n%
FOR /F "delims=" %%L in ("!line!") Do ( %\n%
endlocal %\n%
endlocal %\n%
set "%%~1[%%C]=%%~L" ! %\n%
if %%C == 0 ( %\n%
set "%%~1=%%~L" ! %\n%
) ELSE ( %\n%
set "%%~1=!%%~1!!LF!%%~L" ! %\n%
) %\n%
) %\n%
set /a %%~1.Len+=1 %\n%
) %\n%
) %\n%
) ELSE ( %\n%
%= Used if delayed expansion is disabled =% %\n%
for /F "delims=" %%O in ('"%%~2 | findstr /N ^^"') do ( %\n%
setlocal DisableDelayedExpansion %\n%
set "line=%%O" %\n%
setlocal EnableDelayedExpansion %\n%
set "line="!line:*:=!"" %\n%
for /F %%C in ("!%%~1.Len!") DO ( %\n%
FOR /F "delims=" %%L in ("!line!") DO ( %\n%
endlocal %\n%
endlocal %\n%
set "%%~1[%%C]=%%~L" %\n%
) %\n%
set /a %%~1.Len+=1 %\n%
) %\n%
) %\n%
) %\n%
set /a %%~1.Max=%%~1.Len-1 %\n%
) %\n%
) else setlocal DisableDelayedExpansion^&set argv=
goto :eof
于 2019-01-29T16:14:47.183 回答
8
假设您的应用程序的输出是数字返回码，您可以执行以下操作
application arg0 arg1
set VAR=%errorlevel%
于 2010-02-24T02:37:34.223 回答
3
除了答案之外，您不能在循环的set部分中直接使用输出重定向运算符for（例如，如果您想隐藏用户的 stderror 输出并提供更好的错误消息）。相反，您必须使用插入符号 ( ^) 转义它们：
for /f %%O in ('some-erroring-command 2^> nul') do (echo %%O)
于 2015-07-15T11:46:37.263 回答
2
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
REM Prefer backtick usage for command output reading:
REM ENABLEDELAYEDEXPANSION is required for actualized
REM outer variables within for's scope;
REM within for's scope, access to modified
REM outer variable is done via !...! syntax.
SET CHP=C:\Windows\System32\chcp.com
FOR /F "usebackq tokens=1,2,3" %%i IN (`%CHP%`) DO (
IF "%%i" == "Aktive" IF "%%j" == "Codepage:" (
SET SELCP=%%k
SET SELCP=!SELCP:~0,-1!
)
)
echo actual codepage [%SELCP%]
ENDLOCAL
于 2016-09-01T13:22:26.237 回答
1
我编写了每 5 秒 ping 一次 google.com 并使用当前时间记录结果的脚本。在这里您可以找到变量“commandLineStr”的输出（带索引）
@echo off
:LOOPSTART
echo %DATE:~0% %TIME:~0,8% >> Pingtest.log
SETLOCAL ENABLEDELAYEDEXPANSION
SET scriptCount=1
FOR /F "tokens=* USEBACKQ" %%F IN (`ping google.com -n 1`) DO (
SET commandLineStr!scriptCount!=%%F
SET /a scriptCount=!scriptCount!+1
)
@ECHO %commandLineStr1% >> PingTest.log
@ECHO %commandLineStr2% >> PingTest.log
ENDLOCAL
timeout 5 > nul
GOTO LOOPSTART
于 2018-04-02T12:25:09.433 回答
0
一些宏将命令的输出设置为变量/
直接在命令提示符下
c:\>doskey assign=for /f "tokens=1,2 delims=," %a in ("$*") do @for /f "tokens=* delims=" %# in ('"%a"') do @set "%b=%#"
c:\>assign WHOAMI /LOGONID,my-id
c:\>echo %my-id%
带参数的宏
由于这个宏接受参数作为函数，我认为它是在批处理文件中使用的最简洁的宏：
@echo off
::::: ---- defining the assign macro ---- ::::::::
setlocal DisableDelayedExpansion
(set LF=^
%=EMPTY=%
)
set ^"\n=^^^%LF%%LF%^%LF%%LF%^^"
::set argv=Empty
set assign=for /L %%n in (1 1 2) do ( %\n%
if %%n==2 (%\n%
setlocal enableDelayedExpansion%\n%
for /F "tokens=1,2 delims=," %%A in ("!argv!") do (%\n%
for /f "tokens=* delims=" %%# in ('%%~A') do endlocal^&set "%%~B=%%#" %\n%
) %\n%
) %\n%
) ^& set argv=,
::::: -------- ::::::::
:::EXAMPLE
%assign% "WHOAMI /LOGONID",result
echo %result%
FOR /F 宏
不像前面的宏那么容易阅读。
::::::::::::::::::::::::::::::::::::::::::::::::::
;;set "{{=for /f "tokens=* delims=" %%# in ('" &::
;;set "--=') do @set "" &::
;;set "}}==%%#"" &::
::::::::::::::::::::::::::::::::::::::::::::::::::
:: --examples
::assigning ver output to %win-ver% variable
%{{% ver %--%win-ver%}}%
echo 3: %win-ver%
::assigning hostname output to %my-host% variable
%{{% hostname %--%my-host%}}%
echo 4: %my-host%
使用临时文件的宏
更容易阅读，如果你有一个 SSD 驱动器，它不会那么慢，但它仍然会创建一个临时文件。
@echo off
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;;set "[[=>"#" 2>&1&set/p "&set "]]==<# & del /q # >nul 2>&1" &::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
chcp %[[%code-page%]]%
echo ~~%code-page%~~
whoami %[[%its-me%]]%
echo ##%its-me%##
于 2020-11-09T11:06:37.530 回答