6

我正在尝试编写一个宏，该宏扩展为具有解构的 let 形式。我的问题是我想拥有以 let 形式定义的符号列表，包括通过解构获得的符号列表。

用例

我试图排除这种行为，例如验证：

(let [a (foo bar)
      {x :x,
       y :y,
       {u :u, v: v :as nested-map} :nested} some-map]
  (and x y nested-map u v ; testing truthiness
       (valid-a? a)
       (valid-x? x)
       (valid-y? y)
       (valid-nested? nested-map)
       (valid-u-and-v? u v)
       ))

建议的解决方案

通过某种and-let我可以这样调用的宏来实现这一点真的很好：

(and-let [a (foo bar)
          {x :x,
           y :y,
           {u :u, v: v :as nested-map} :nested} some-map]
         (valid-a? a)
         (valid-x? x)
         (valid-nested? nested-map)
         (valid-u-and-v? u v))

我错过了什么

但是我缺少某种访问以 let 形式绑定的符号列表的方法。如果我有类似list-bound-symbols函数的东西，我可以这样做：

(defmacro and-let
  "Expands to an AND close that previouly checks that the values declared in bindings are truthy, followed by the tests."
  [bindings & tests]
  (let [bound-symbols (list-bound-symbols bindings) ;; what I'm missing
        ]
    `(let ~bindings
       (and 
         ~@bound-symbols
         ~@tests)
     )))

有没有人知道我该怎么做？

4

2 回答 2

5

解构由clojure.core/destructure函数处理。它是公开的，因此我们可以自己调用它并提取所有本地人的名称，包括那些命名用于解构的中间结果的名称：

(defmacro and-let [bindings & tests]
  (let [destructured (destructure bindings)]
    `(let ~destructured
       (and ~@(take-nth 2 destructured)
            ~@tests))))

似乎工作：

(let [foo nil]
  (and-let [a 1
            [b c] [2 3]]
    (nil? foo)))
;= true
于 2014-04-22T10:25:23.933 回答
0

您可以使用直接处理地图的函数来完成大部分操作。

(defn validate [vm ; validation map
                dm ; data map
                ]
  (and
    (every? identity (map #(% dm) (flatten (keys vm))))
    (every? identity (map (fn [[k vf]]
                            (if (vector? k)
                              (apply vf (map #(% dm) k))
                              (vf (k dm))))
                          vm))))

例如

(validate {:s string?, :n number? :m number? [:m :n] > } {:s "Hello!", :m 5, :n 3})
; true

(validate {:s string?, :n number? :m number? [:m :n] > } {:s "Hello!", :m 5, :n 6})
; false

(validate {:s string?, :n number? :m number? :u \b [:m :n] > } {:s "Hello!", :m 5, :n 6})
; false

a在您的示例中，您可以预先将任何无关变量添加到地图中。这将不必要地测试as 的真实性。没有造成伤害？

于 2014-04-22T11:30:56.467 回答