datomic - Datomic 聚合使用情况

Question

我想通过下一个查询找到年龄最小的人

(d/q '[:find ?name (min ?age)
         :in [[?name ?age]]]
       [["John" 20]
        ["Bill" 25]
        ["Jack" 20]
        ["Steve" 28]
        ["Andrew" 30]])

但结果是

[["Andrew" 30] ["Bill" 25] ["Jack" 20] ["John" 20] ["Steve" 28]]

怎么做？

Answer 1

您可以使用子查询（从查询内部而不是外部查询调用），而不是将查询链接在一起：

(d/q '[:find ?name ?mage
       :in $
       :where [(datomic.api/q '[:find (min ?age)
                                :where [_ :age ?age]]
                              $) [[?mage]]]
              [?name :age ?mage]]
   [["John" :age 20]
    ["Bill" :age 25]
    ["Jack" :age 20]
    ["Steve" :age 28]
    ["Andrew" :age 30]])

回报：

#{["John" 20] ["Jack" 20]}

Answer 2

这将是一个纯粹的 Datalog 解决方案

(let [db [["John" 20]
          ["Bill" 25]
          ["Jack" 20]
          ["Steve" 28]
          ["Andrew" 30]]]
  (d/q '[:find ?name ?min-age
         :in $ ?min-age
         :where [?name ?min-age]]
       db
       (ffirst (d/q '[:find (min ?age)
                      :in [[?name ?age]]]
                 db))))

SQL 中的 HAVING 子句不是查询语言的一部分，但由于所有查询都在对等方中执行，因此执行嵌套查询没有开销。

Answer 3

在这种情况下，您不需要 datomic，因为您的序列中已经拥有所有需要的数据。请改用 clojure排序。

(first (sort-by second [...]))