13

我正在尝试让一些旧的 VB6 代码与 SQL Server Compact 一起使用。

我可以连接，打开数据库，一切似乎都很好。我可以运行有效的插入选择命令。

但是，即使我可以访问字段并查看数据，ADODB.Recordset RecordCount 属性也始终返回 -1。更改 CursorLocation = adUseClient 会导致执行 SQL 时出现问题（多步操作产生错误）。

Option Explicit
    Private Const mSqlProvider          As String = "Provider=Microsoft.SQLSERVER.CE.OLEDB.3.5;"
    Private Const mSqlHost              As String = "Data Source=C:\Database.sdf;"
    Private mCmd                        As ADODB.Command   ' For executing SQL
    Private mDbConnection               As ADODB.Connection


Private Sub Command1_Click()


   Dim rs As ADODB.Recordset

    Set rs = New ADODB.Recordset


    Dim DbConnectionString As String

    DbConnectionString = mSqlProvider & _
                            mSqlHost


    Set mDbConnection = New ADODB.Connection
    mDbConnection.CursorLocation = adUseServer

    Call mDbConnection.Open(DbConnectionString)

    If mDbConnection.State = adStateOpen Then
        Debug.Print (" Database is open")
        ' Initialise the command object
        Set mCmd = New ADODB.Command
        mCmd.ActiveConnection = mDbConnection

        mCmd.CommandText = "select * from myTestTable"
        mCmd.CommandType = adCmdText

        Set rs = mCmd.Execute

        Debug.Print rs.RecordCount  ' Always returns -1  !!
        Debug.Print rs.Fields(0)   ' returns correct data for first row, first col
        Debug.Print rs.Fields(1)   ' returns correct data for first row, 2nd col
        Debug.Print rs.Fields(2)   ' returns correct data for first row, 3rd col

    End If

End Sub

任何建议将不胜感激。

4

13 回答 13

8

实际上，CursorLocation在这种情况下起主要作用。用于rs.CursorLocation = adUseClient设置光标位置并尝试。

    Set rs = New ADODB.Recordset
    rs.CursorLocation = adUseClient
    Dim DbConnectionString As String

    DbConnectionString = mSqlProvider & _
                            mSqlHost


    Set mDbConnection = New ADODB.Connection
    mDbConnection.CursorLocation = adUseServer

    Call mDbConnection.Open(DbConnectionString)

    If mDbConnection.State = adStateOpen Then
        Debug.Print (" Database is open")
        ' Initialise the command object
        Set mCmd = New ADODB.Command
        mCmd.ActiveConnection = mDbConnection

        mCmd.CommandText = "select * from myTestTable"
        mCmd.CommandType = adCmdText

        Set rs = mCmd.Execute

        Debug.Print rs.RecordCount  ' This should now return the right value.
        Debug.Print rs.Fields(0)   ' returns correct data for first row, first col
        Debug.Print rs.Fields(1)   ' returns correct data for first row, 2nd col
        Debug.Print rs.Fields(2)   ' returns correct data for first row, 3rd col

    End If

End Sub
于 2010-02-18T16:57:53.703 回答
3

这是用于访问数据的游标类型的结果，这篇文章涵盖了问题和可能的修复。

http://www.devx.com/tips/Tip/14143

编辑

我很抱歉没有更注意您正在处理 Compact 的事实。使用 Compact 时，情况与我引用的情况类似，因为它默认使用仅向前游标（不支持行计数），但还有其他两种可用的游标类型，如下面的链接中所述。

http://support.microsoft.com/kb/272067

于 2010-02-17T17:00:16.650 回答
3

从很久以前使用 VB6/ADO 的内存中，.RecordCount 字段不会返回有意义的数据，直到您移动到记录集的末尾。

rs.MoveLast
rs.MoveFirst
Debug.Print rs.RecordCount

尽管有了这个，你需要确保你有适当的光标类型（即，不仅仅是向前的）。

我能想到的唯一其他解决方案是执行单独的 SELECT COUNT(*) FROM myTestTable 等，但这会导致该调用与实际返回行的调用之间的数据更改存在问题。

于 2010-02-18T17:23:50.443 回答
2

使用 Compact 时，默认光标属性是 adOpenForwardOnly 以提高性能。因此，RecordCount 返回为“-1”，这意味着它不可用，而不是空白。这是设计使然，因为动态游标中的记录数可能会更改并导致在客户端服务器之间来回 ping 以保持准确性。但是，如果记录计数至关重要，请尝试将其设置为使用带有服务器端游标的 adOpenKeyset 或 adOpenStatic。

于 2010-02-19T14:06:38.290 回答
2

这是我使用的解决方案

Dim recordnumber As Long
Dim SalRSrec As New ADODB.Recordset
Set SalRSrec = Nothing
SalRSrec.Open ("SELECT count(*) from SALARY where EMPID= '" & cmb_empid & "' ;"), Dbase, adOpenKeyset, adLockOptimistic
recordnumber = SalRSrec.GetString
MsgBox recordnumber
于 2012-12-15T07:46:37.433 回答
2

检查记录集属性

以下是 com.status.live 代码返回的 RecordCount 值的结果

+------------------+-------------------+-------------+---------------+--------------+
|    CursorTypeEnum|adOpenForwardOnly=0|dOpenKeyset=1|adOpenDynamic=2|adOpenStatic=3|
|CursorLocationEnum|                                                                |
+------------------+-------------------+-------------+---------------+--------------+
|adUseServer = 2   |         X         |      O      |       X       |       O      |
|adUseClient = 3   |         O         |      O      |       O       |       O      |
+------------------+-------------------+-------------+---------------+--------------+
于 2012-11-20T03:24:15.437 回答
1

如果仍然返回 -1，请尝试使用以下代码

Set Conn = createobject("ADODB.connection")
Set Rs = createobject("ADODB.recordset")
Conn.Open "DSN=DSN_QTP" 
'Rs.Open "Select * From orders",Conn,adOpenDynamic,adLockBatchOptimistic
Rs.Open "Select * from [QTP-Table]",Conn,1 'Use either 1 or 3
'I tried using adopendynamic but it still returned -1. Using 1 it gave me correct count.       'Though I am using this code in QTP (Vbscript) same should work for VB6 also.
msgbox Rs.RecordCount
于 2013-12-15T17:24:48.887 回答
1

替换Set rs = mCmd.Execute为：

set rs = new ADODB.Recordset
rs.Open "select * from myTestTable", mDBConnection, adOpenDynamic, adLockOptimistic

这adOpenDynamic将允许向前/向后读取以获取您的记录数。

于 2010-02-17T22:46:20.053 回答
1

你可以试试这样的..

Set rs = mCmd.Execute

rs.MoveFirst

Do Until rs.EOF = true

    Debug.Print rs.RecordCount  ' Always returns -1  !!
    Debug.Print rs.Fields(0)   ' returns correct data for first row, first col
    Debug.Print rs.Fields(1)   ' returns correct data for first row, 2nd col
    Debug.Print rs.Fields(2)   ' returns correct data for first row, 3rd col

   counter = counter + 1
   rs.MoveNext

Loop
于 2013-12-20T01:52:08.340 回答
0

下面的代码可能会对您有所帮助，

set conn = CreateObject("ADODB.Connection") 
conn.open "<connection string>" 
set rs = CreateObject("ADODB.Recordset") 
sql = "SELECT columns FROM table WHERE [...]" 
rs.open sql,conn,1,1 
if not rs.eof then 
    nr = rs.recordcount 
    response.write "There were " & nr & " matches." 
    ' ... process real results here ... 
else 
    response.write "No matches." 
end if 
rs.close: set rs = nothing 
conn.close: set conn = nothing
于 2011-02-14T07:36:25.713 回答
0

you must set the CONNECTIOn to aduseClient, no recordset and be carefoul to set only a new connection, if you use the same connection in your proyect, you can get other errors.

CRAETE A NEW CONNEXTION with aduseclient

Dim Sql As String
Dim CnCommand As New ADODB.Connection

On Error GoTo VerError:
Dim Comando As ADODB.Command
Set Comando = New ADODB.Command
CnCommand.ConnectionString = Cn.ConnectionString 'your exist connection in application
CnCommand.Open
CnCommand.CursorLocation = adUseClient
Set Comando.ActiveConnection = CnCommand

'Comando.ActiveConnection.CursorLocation = adUseClient
    
    Comando.Parameters.Append Comando.CreateParameter("@Usuario", adInteger, adParamInput, , V_General.Usuario.Codigo)
    
    Comando.CommandType = adCmdStoredProc
    
    Comando.CommandText = "SP_Contratac"
    Dim Rs As Recordset
    Set Rs = New ADODB.Recordset
    Set Rs = Comando.Execute()
于 2021-10-25T17:09:21.083 回答
0 
Set cn = CreateObject("ADODB.Connection")

strVerb = "Provider=Microsoft.ACE.OLEDB.12.0;" & _
    "Data Source=C:\test.accdb"

tab1 = "tabelle1"

strSQL = "SELECT Count(*) FROM " & tab1

Debug.Print strSQL
         
cn.Open strVerb
Set rs = cn.Execute(strSQL)

Debug.Print rs.Fields(0)
    
rs.Close
Set rs = Nothing
cn.Close
Set cn = Nothing
于 2020-08-14T11:50:41.113 回答
-1

以下代码准确返回记录计数...

Public Sub test()
    Dim cn As New ADODB.Connection()
    Dim sPath As String = Application.ExecutablePath
    sPath = System.IO.Path.GetDirectoryName(sPath)

    If sPath.EndsWith("\bin") Then
        sPath = sPath.Substring(0, Len(sPath) - 4)
    End If

    Dim DbConnectionString As String
    DbConnectionString = "provider=microsoft.jet.oledb.4.0;data source=" & sPath & "\students.mdb"

    cn.ConnectionString = DbConnectionString
    cn.Open()

    Dim rs As New ADODB.Recordset()
    rs.CursorLocation = ADODB.CursorLocationEnum.adUseClient
    rs.CursorType = ADODB.CursorTypeEnum.adOpenStatic
    rs.LockType = ADODB.LockTypeEnum.adLockBatchOptimistic
    rs.Open("select * from students", cn)
    MsgBox(rs.RecordCount)

    rs.ActiveConnection = Nothing
    cn.Close()
End Sub
于 2010-02-23T13:53:57.323 回答