qt - QML StackView 自定义过渡

Question

我已经浏览了 Qt 文档：Qt StackView但我仍然无法弄清楚我做错了什么，因为我的代码应该产生淡入/淡出动画，但我得到的只是内容之间的瞬间闪烁。我希望我的描述是充分和清楚的。

StackView {
    id: stackView
    anchors.fill: parent
    delegate: StackViewDelegate {

        function transitionFinished(properties)
        {
            properties.exitItem.opacity = 1
        }

        property Component pushTransition: StackViewTransition {
            PropertyAnimation {
                target: enterItem
                property: "opacity"
                from: 0
                to: 1
                duration: 10
            }
            PropertyAnimation {
                target: exitItem
                property: "opacity"
                from: 1
                to: 0
                duration: 10
            }
        }
    }
    initialItem: Item {
        width: parent.width
        height: parent.height
        ListView {
            model: pageModel
            anchors.fill: parent
            delegate: AndroidDelegate {
                text: title
                onClicked: stackView.push(Qt.resolvedUrl(page))
            }
        }
    }
}

Answer 1

我遇到了同样的问题并请求他们的支持——他们的例子是错误的。

代替

property Component pushTransition: StackViewTransition {

和

pushTransition: StackViewTransition {

它应该可以工作。pushTransition 实际上是 StackViewDelegate 上的一个属性

我仍在尝试让 transitionFinished 函数工作，因为他们的示例也不起作用。

Answer 2

动画的持续时间为 10 毫秒，或 1/100 秒。

Answer 3

这对我有用：

Window {
    id: mainWindowId
    width: 1280
    height: 800

    StackView {
       id: stackViewId
       anchors.fill: parent

      replaceEnter: Transition {
          PropertyAnimation{
              property: "opacity"
              from: 0
              to: 1
              duration: 300
          }
      }

      replaceExit: Transition {
          PropertyAnimation{
              property: "opacity"
              from: 1
              to: 0
              duration: 250
          }
      }

      initialItem: "yourStartingPage.qml"

    }
}

对于改变观点：

stackViewId.replace("yourOtherPage.qml")