2

我了解如何使用单子，但我并不真正掌握如何创建单子。所以我正在重建一个状态单子的旅程。

到目前为止，我已经创建了一个新类型 Toto（法语中的 foo）并将其作为 Monad 的一个实例。现在我正在尝试为其添加“阅读器功能”。我创建了一个 TotoReader 类，它声明了一个“get”函数。但是当我尝试实例化它时，一切都崩溃了。GHC 告诉我它无法推断 (m ~ r) （底部的完整编译错误）。

但是当我创建一个顶级函数 get 时，一切正常。

那么如何在一个类中定义一个 get 函数，它真的是正确的方法吗？什么是我不明白的？

到目前为止我的代码如下

{-# OPTIONS -XMultiParamTypeClasses #-}
{-# OPTIONS -XFlexibleInstances #-}

newtype Toto s val = Toto { runToto :: s -> (val, s) }

toto :: (a -> (b,a)) -> Toto a b
toto = Toto

class (Monad m) => TotoReader m r where
    get :: m r

instance Monad (Toto a) where
    return a = toto $ \x -> (a,x)
    p >>= v  = toto $ \x ->
                    let (val,c) = runToto p x
                    in runToto (v val) c

instance TotoReader (Toto m) r where 
    get = toto $ \x -> (x, x) -- Error here

-- This is working
-- get :: Toto a b
-- get = toto $ \s -> (s,s)


pp :: Toto String String
pp = do 
    val <- get
    return $ "Bonjour de " ++ val

main :: IO ()
main = print $ runToto pp "France"

编译错误

test.hs:19:11:
    Could not deduce (m ~ r)
    from the context (Monad (Toto m))
      bound by the instance declaration at test.hs:18:10-30
      `m' is a rigid type variable bound by
          the instance declaration at test.hs:18:10
      `r' is a rigid type variable bound by
          the instance declaration at test.hs:18:10
    Expected type: Toto m r
      Actual type: Toto m m
    In the expression: toto $ \ x -> (x, x)
    In an equation for `get': get = toto $ \ x -> (x, x)
    In the instance declaration for `TotoReader (Toto m) r'
4

1 回答 1

4

让我们使用ghci来检查种类：

*Main> :k Toto
Toto :: * -> * -> *

Toto接受两个类型参数：环境类型和返回类型。如果r是环境，Toto r将是 monad 类型构造函数。

*Main> :k TotoReader
TotoReader :: (* -> *) -> * -> Constraint

TotoReader接受两个类型参数：monad 类型构造函数和环境类型，在我们的例子中分别是Toto r和r。

所以，实例声明应该是这样的：

instance TotoReader (Toto r) r where 
    get = toto $ \x -> (x, x)
于 2014-03-30T10:18:50.577 回答